//Le Livre d'Ymir http://www.bookofymir.net/
//traduit par No Healing
//===== eAthena Script =======================================
//= Platinum Skills
//===== By: ==================================================
//= Keichii, DarkChild
//===== Current Version: =====================================
//= 2.8
//===== Compatible With: =====================================
//= eAthena SVN
//===== Description: =========================================
//= Single NPC that assigns quests skills for all classes
//===== Additional Comments: =================================
//= 2.0 Added advanced classes by ShadowLady.
//= 2.1 Added baby clases by Midas
//= 2.2 Simplified Job Checks [Silentdragon]
//= 2.3 Thehell? Cleaned up script removed the nastiness. Also added rebirth skills. [Spre]
//= 2.4 Added Advanced skills. [Spre]
//= 2.5 Added dialog for if the user is none of the listed jobs. [Kisuka]
//= 2.6 Fixed 2nd advanced classes not being able to get their advanced skills. [Ancyker]
//= 2.7 Rewrote to give all correct skills to all proper classes. [Paradox924X]
//= 2.8 Clustered conditionals replaced with switch to include all Upper types. [Euphy]
//============================================================

prontera,128,200,6	script	Compétences de Platine::Platinum Skill NPC	94,{
	mes "[Compétences de Platine]";
	mes "Je peux vous donner les compétences spéciales disponibles pour votre Classe. Voudriez-vous les recevoir maintenant?";
	next;
	if (select("Oui, s'il vous plaît:Non") == 2) {
		mes "[Compétences de Platine]";
		mes "Passez une bonne "+ ( isday() ? "journée" : "soirée" ) +"... >.>";
		close;
	}
	skill 142,1,0;
	switch(BaseClass) {
		case 0: if (Class !=23) skill 143,1,0; break;
		case 1: skill 144,1,0; skill 145,1,0; skill 146,1,0; break;
		case 2: skill 157,1,0; break;
		case 3: skill 147,1,0; skill 148,1,0; break;
		case 4: skill 156,1,0; break;
		case 5: skill 153,1,0; skill 154,1,0; skill 155,1,0; break;
		case 6: skill 149,1,0; skill 150,1,0; skill 151,1,0; skill 152,1,0; break;
		default: break; }
	switch(roclass(eaclass()&EAJ_UPPERMASK)) {
		case 7: skill 1001,1,0; break;
		case 8: skill 1014,1,0; break;
		case 9: skill 1006,1,0; break;
		case 10: skill 1012,1,0; skill 1013,1,0; break;
		case 11: skill 1009,1,0; break;
		case 12: skill 1003,1,0; skill 1004,1,0; break;
		case 14: skill 1002,1,0; break;
		case 15: skill 1015,1,0; skill 1016,1,0; break;
		case 16: skill 1007,1,0; skill 1008,1,0; skill 1017,1,0; skill 1018,1,0; skill 1019,1,0; break;
		case 17: skill 1005,1,0; break;
		case 18: skill 238,1,0; break;
		case 19: skill 1010,1,0; break;
		case 20: skill 1011,1,0; break;
		default: break; }

	mes "[Compétences de Platine]";
	mes "Et voilà, c'est fait!";
	close;
}