//Le Livre d'Ymir http://www.bookofymir.net/
//traduit par Myllena, corrigé par Morrigan
//===== eAthena Script ======================================= 
//= Advance Class jobchanger after kRO Normals.
//===== By: ==================================================
//= Nana
//= finished, optimized and tested by Lupus
//===== Current Version: ===================================== 
//= 1.3
//===== Compatible With: ===================================== 
//= eAthena 1.0 +
//===== Description: ========================================= 
//= Advance Class jobchanger after kRO Normals.
//===== Additional Comments: ================================= 
//= v1.1 Made all into functions, additional checks, etc. [Lupus]
//= v1.2 Made numbers into constants. [Vicious]
//= 1.3 Now saves/restores all the quest skills [Lupus]
//============================================================ 

valkyrie,53,58,3	script	Rôdeuse::Rôdeur#Valkyrie	747,{
	if (ADVJOB == 0 || Upper != 1) {
		set .@karma_d,rand(1,10);
		if (.@karma_d > 4) {
			mes "[Rôdeuse]";
			mes "Félicitations.";
			mes "Honneur aux Guerriers!";
			close;
		}
		mes "[Rôdeuse]";
		mes "Hé...";
		mes "Ce n'est pas facile d'être à la fois "+ ( sex ? "un héros" : "une héroïne" ) +", tout en devant rester caché"+ ( sex ? "" : "e" ) +" dans l'ombre, incompris...";
		next;
		mes "[Rôdeuse]";
		mes "Mais quand les temps s'assombrissent, vos amis savent qu'ils peuvent compter sur vous. Ils ont besoin de vous, et vous avez besoin d'eux.";
		close;
	}
	else if (ADVJOB == Job_Stalker && Class == Job_Thief_High && JobLevel > 39) {
		mes "[Rôdeuse]";
		mes "Le monde a besoin de héros qui marchent sur la ligne entre l'ordre et le chaos.";
		next;
		mes "[Rôdeuse]";
		mes "Souhaitez-vous devenir Rôdeur?";
		next;
		if (select("Non.:Oui.") == 1) {
			mes "[Rôdeuse]";
			mes "Revenez quand vous vous sentirez prêt"+ ( sex ? "" : "e" ) +".";
			next;
			mes "[Rôdeuse]";
			mes "Honneur aux Guerriers!";
			close;
		}
		if (SkillPoint) {
			mes "[Rôdeuse]";
			mes "Vous n'avez pas terminé votre apprentissage.";
			close;
		}
		jobchange Job_Stalker;
		set ADVJOB,0;
		mes "[Rôdeuse]";
		mes "Félicitations!";
		mes "En tant que Rôdeur, j'espère que vous poignarderez les bonnes personnes dans le dos.";
		close;
	}
	mes "[Rôdeuse]";
	mes "Bienvenue au Walhalla, le Hall des Honneurs.";
	next;
	mes "[Rôdeuse]";
	mes "Faites comme chez vous.";
	mes "Honneur aux Guerriers!";
	close;
}