//Le Livre d'Ymir http://www.bookofymir.net/
//traduit par Myllena
//===== eAthena Script =======================================
//= Al De Baran Kafras
//===== By: ============================
//= eAthena Dev Team
//===== Current Version: =======================
//= 2.3a
//===== Compatible With: ============================
//= eAthena 1.0
//===== Description: ============================================
//= Description of argument settings for callfunc "F_Kafra".
//=  arg(0): When set at 0 the default Kafra message is displayed.
//=    When set to 1 the Niflhiem Kafra message is displayed.
//=    When set to 2 the Guild Kafra message is displayed. 
//=  arg(1): Set to 1 to disable teleport menu option. Otherwise set to 0.
//=  arg(2): Set to 1 to disable info menu.  Otherwise set to 0.
//=  arg(3): Cost of Storage service
//=  arg(4): Cost of Rent a Pushcart service
//===== Additional Comments: ==========================================
//= v1.1 Now using functions :)
//= v2.1b Minor changes to function calls. Using arguments.
//= This version uses arrays .[kobra_k88]
//= 2.2 New teleport destinations, prices [Lupus]
//= 2.3 Updated function calls with new arguments. [L0ne_W0lf]
//=	Kafra Leilah is now a full NPC and no longer uses functions.
//=	Added unique Kafra Welcome message.
//=	Changed "Yuno" to "Juno"
//= 2.3a Added "callfunc("F_CheckKafCode")" when you open storage. (bugreport:515) [Samuray22]
//=====================================================================

// Kafra Main Office (Kafra Leilah) ------------------------------------
aldeba_in,96,181,4	script	Employée Kafra	113,{
	cutin "kafra_05",2;
	mes "[Kafra Leilah]";
	mes "Hum...?";
	mes "Oh, bienvenue au Quartier Général";
	mes "de la Corporation Kafra.";
	mes "Est-ce que vous avez";
	mes "besoin de quelque chose?";
	next;
	switch(select("Sauvegarder:Ouvrir le Stock:Louer une Charrette:Rien, merci")) {
	case 1:
		mes "[Kafra Leilah]";
		mes "Votre Point de Sauvegarde";
		mes "a été enregistré ici, au";
		mes "Quartier Général de la";
		mes "Corporation Kafra. Merci.";
		next;
		savepoint "aldeba_in",96,179;
		mes "[Kafra Leilah]";
		mes "N'hésitez pas à utiliser les";
		mes "Services Kafra disponibles";
		mes "dans tout le royaume de";
		mes "Rune Midgard. Merci d'avoir";
		mes "visité le Q.G. Kafra.";
		close2;
		break;
	case 2:
		if (zeny < 20) {
			mes "[Kafra Leilah]";
			mes "Je suis désolée, mais";
			mes "il semblerait que vous";
			mes "n'ayez pas les 20 Zénys";
			mes "nécessaires pour ouvrir le Stock...";
			close;
		}
		mes "[Kafra Leilah]";
		mes "Bien que ce service soit";
		mes "exclusivement proposé par les";
		mes "Employées Kafras sur le terrain,";
		mes "exceptionnellement je vais vous";
		mes "donner accès à votre Stock.";
		next;
		set zeny,zeny-20;
		set RESRVPTS, RESRVPTS + (20/5);
		mes "[Kafra Leilah]";
		mes "La prochaine fois, veuillez";
		mes "vous adresser à une Employée Kafra";
		mes "du terrain, et non à moi qui suis";
		mes "uniquement dans l'administration.";
		mes "Merci de votre compréhension.";
		callfunc("F_CheckKafCode");    //check your storage password, if set
		close2;
		openstorage;
		break;
	case 3:
		mes "[Kafra Leilah]";
		mes "Je suis désolée, mais je ne puis vous fournir ce service. Je vous aiderais si je le pouvais, mais nous n'avons plus de Charrettes disponibles. Pourquoi ne pas demander à une autre Employée Kafra?";
		next;
		mes "[Kafra Leilah]";
		mes "Les Employées Kafras se situent dans tout le continent de Rune Midgard, vous ne devriez donc pas avoir de mal à en trouver, par exemple ici à Al De Baran.";
		close2;
		break;
	case 4:
		mes "[Kafra Leilah]";
		mes "^666666*Pfiou...*^000000";
		mes "Super, parce qu'en fait";
		mes "je comptais faire une petite";
		mes "pause... Et oui le métier";
		mes "de Kafra n'est pas de";
		mes "tout repos... ~";
		close2;
		break;
	}
	cutin "",255;
	end;
}

// Central --------------------------------------------------
aldebaran,143,119,4	script	Employée Kafra::kaf_aldebaran	113,{
	cutin "kafra_05",2;
	cleararray @wrpC$[0],"",getarraysize(@wrpC$);
	setarray @wrpP[0], 1200, 1200, 1800, 1700;
	setarray @wrpD$[0], "Geffen", "Yuno" , "Izlude", "Mont de la Mort de Mjolnir";
	set @wrpC$[0], @wrpD$[0]+" -> "+@wrpP[0];
	set @wrpC$[1], @wrpD$[1]+" -> "+@wrpP[1];
	set @wrpC$[2], @wrpD$[2]+" -> "+@wrpP[2];
	set @wrpC$[3], @wrpD$[3]+" -> "+@wrpP[3];
	set @wrpC$[4], "Annuler";
	mes "[Employée Kafra]";
	mes "La Corporation Kafra vous accompagne où que vous alliez pour vous fournir les meilleurs services.";
	mes "En quoi puis-je vous aider?";
	callfunc "F_Kafra",5,0,1,20,600;

	M_Save:
		savepoint "aldebaran",143,109;
		callfunc "F_KafEnd",0,1,"dans la ville d'Al De Baran";
}