//= Le Livre d'Ymir http://www.bookofymir.net/
//= traduit par Elianor, corrigé par Myllena
//===== eAthena Script =======================================
//= Auction system
//===== By: ==================================================
//= L0ne_W0lf
//===== Current Version: =====================================
//= 1.3
//===== Compatible With: =====================================
//= eAthena SVN
//===== Description: =========================================
//= [Aegis Conversion]
//= Auction house releated NPCs, and warps
//===== Additional Comments: =================================
//= 1.0 First version, place holders only. [L0ne_W0lf]
//= 1.1 Moved Morroc Auction NPCs to Morroc Ruins. [L0ne_W0lf]
//= 1.2 Warp fixed. Dialog in Ruins/Lighthalzen changed. [Kisuka]
//= 1.3 Duplicates now spawn from floating NPCs. [L0ne_W0lf]
//============================================================

// Auction House warpers
//============================================================
moc_ruins,78,173,6	script	Salle des Enchères#moc	98,{
	callfunc "F_AuctionWarper",1;
}

prontera,218,120,4	script	Salle des Enchères#prt	117,{
	callfunc "F_AuctionWarper",2;
}

yuno,129,116,0	script	Salle des Enchères#yuno	90,{
	callfunc "F_AuctionWarper",3;
}

lighthalzen,205,169,6	script	Salle des Enchères#lhz	833,{
	callfunc "F_AuctionWarper",4;
}

function	script	F_AuctionWarper	{
	mes "[Guide des Enchères]";
	mes ( isday() ? "Bonjour" : "Bonsoir" ) + ", désirez-vous entrer dans la salle de vente aux enchères?";
	next;
	if (select("Oui:Non") == 1) {
		if (getarg(0) == 1 || getarg(0) == 4) {
			mes "[Guide des Enchères]";
			mes "Très bien! Alors je vous souhaite de bien vous amuser et de profiter des enchères~";
		}else{
			mes "[Guide des Enchères]";
			mes "Faites de bonnes enchères.";
		}
		close2;
		switch(getarg(0)) {
		case 1:
			warp "auction_01",179,53; end;
		case 2:
			warp "auction_01",21,43; end;
		case 3:
			warp "auction_02",151,23; end;
		case 4:
			warp "auction_02",43,24; end;
		}
	}
	mes "[Guide des Enchères]";
	mes "Très bien, à plus tard.";
	mes "Si vous changez d'avis, revenez pour profiter des enchères~";
	close;
}

// Sign posts
//============================================================
-	script	Informations#dum::AuctionSign	-1,{
	mes "[Informations]";
	mes "Téléportation vers la salle de ventes aux enchères.";
	close;
}

moc_ruins,76,176,6	duplicate(AuctionSign)	Informations#moc	837
prontera,216,120,4	duplicate(AuctionSign)	Informations#prt	837
yuno,131,116,0	duplicate(AuctionSign)	Informations#yunauc	837
lighthalzen,207,169,6	duplicate(AuctionSign)	Informations#lhz	837

// Warps
//============================================================
auction_01,180,49,0	warp	auction_entrance_moc	1,1,moc_ruins,78,171
auction_01,22,37,0	warp	auction_entrance_prt	1,1,prontera,214,120
auction_02,151,17,0	warp	auction_enterance_juno	1,1,yuno,132,119
auction_02,43,17,0	warp	auction_enterance_lhz	1,1,lighthalzen,209,169

// Auction House NPCs
//============================================================
-	script	Commissaire-Priseur#du::AuctionBroker	-1,{
	mes "[Commissaire-Priseur]";
	mes "Bienvenue à la Salle des Enchères.";
	mes "Souhaitez-vous voir les objets?";
	next;
	if (select("Oui:Non") == 1) {
		mes "[Commissaire-Priseur]";
		mes "Très bien.";
		mes "Prenez le temps de jeter un coup d'oeil, et voir tout ce qui est proposé~";
		OpenAuction;
		close;
	}
	mes "[Commissaire-Priseur]";
	mes "Comme vous voulez.";
	mes "Si vous changez d'avis n'hésitez pas à revenir voir les enchères~";
	close;
}

auction_01,182,68,6	duplicate(AuctionBroker)	Commissaire-Priseur#mo1	98
auction_01,182,75,0	duplicate(AuctionBroker)	Commissaire-Priseur#mo2	99
auction_01,177,75,2	duplicate(AuctionBroker)	Commissaire-Priseur#mo3	98
auction_01,177,68,4	duplicate(AuctionBroker)	Commissaire-Priseur#mo4	99
auction_01,21,74,4	duplicate(AuctionBroker)	Commissaire-Priseur#pr1	117
auction_01,27,78,4	duplicate(AuctionBroker)	Commissaire-Priseur#pr2	116
auction_01,16,78,4	duplicate(AuctionBroker)	Commissaire-Priseur#pr3	115
auction_02,158,47,6	duplicate(AuctionBroker)	Commissaire-Priseur#yu1	90
auction_02,145,47,2	duplicate(AuctionBroker)	Commissaire-Priseur#yu2	90
auction_02,151,54,0	duplicate(AuctionBroker)	Commissaire-Priseur#yu3	90
auction_02,152,41,4	duplicate(AuctionBroker)	Commissaire-Priseur#yu4	90
auction_02,57,46,2	duplicate(AuctionBroker)	Commissaire-Priseur#lh1	874
auction_02,31,46,6	duplicate(AuctionBroker)	Commissaire-Priseur#lh2	874
auction_02,43,65,4	duplicate(AuctionBroker)	Commissaire-Priseur#lh3	833