//Le Livre d'Ymir http://www.bookofymir.net/
//traduit par Myllena
//===== eAthena Script ======================================= 
//= Quest NPCs related to Lutie
//===== By: ================================================== 
//= TonyMan & Samuray22
//===== Current Version: ===================================== 
//= 1.3b
//===== Compatible With: ===================================== 
//= eAthena 1.0
//===== Description: ========================================= 
//= Blush, Cake Hat, Candle, Chef Hat, Raccoon Hat, Rainbow Eggshell,
//= Spore Hat, Wonder Nutshell Quests
//===== Additional Comments: ================================= 
//= 1.1 Optimized [Lupus]
//= 1.2 Fixed Chef Hat items [Lupus]
//= 1.3 Update NPC to the Official One. [Samuray22]
//= 1.3a Changed item names to item IDs. [Samuray22]
//= 1.3b Removed a scrap " left in a delitem. [L0ne_W0lf]
//= 1.4 Updated NPCs once again. [L0ne_W0lf]
//============================================================ 

xmas,117,295,4	script	Titicupe	704,{
	mes "[Titicupe]";
	mes "Hum...?";
	mes ( isday() ? "Bonjour" : "Bonsoir" ) + "! Je suis Titicupe, estimé manager de la Fabrique de Jouets, et inventeur de génie! J'ai récemment créé un automate très sophistiqué qui distribue des chapeaux uniques en leur genre!";
	next;
	switch(select("Informations sur l'automate.:Informations sur les chapeaux.:S'en aller.")) {
	case 1:
		mes "[Titicupe]";
		mes "Vous voyez le petit bonhomme de neige à ma gauche? Si vous regardez sa bouche de plus près, vous verrez qu'un espace d'insertion a été prévu...";
		next;
		mes "[Titicupe]";
		mes "Car voyez-vous, ce bonhomme de neige est en fait un automate très sophistiqué de mon invention!";
		next;
		mes "[Titicupe]";
		mes "Vous pouvez insérer tout un tas de choses dans sa bouche, et en échange il vous rendra un autre objet, en particulier des chapeaux...";
		next;
		mes "[Titicupe]";
		mes "Ne trouvez-vous pas mon invention absolument superbe?";
		Emotion e_kis2;
		next;
		mes "[Titicupe]";
		mes "Tous ces chapeaux--! Je... Je ne peux plus me contenir!";
		next;
		mes "^3355FFTiticupe sautille dans tous les sens, visiblement empreint à une convulsion de joie. Il est complètement fou, c'est une évidence.^000000";
		Emotion e_gasp;
		close;
	case 2:
		mes "[Titicupe]";
		mes "Oh, d'accord! Vous voulez des informations à propos de mes créations? Allez-y... demandez-moi~";
		Emotion e_ic;
		next;
		switch(select("Chapeau de Raton-Laveur:Chapeau de Spore:Coquille de Noix Laquée:Coquille Arc-en-Ciel:Pommettes:Toque:Bougie Décorative:Gâteau d'Anniversaire:Rien, merci")) {
		case 1:
			mes "[Titicupe]";
			mes "Le Chapeau de Raton-Laveur? Pour le fabriquer, j'ai besoin de:";
			mes "1 paire d'Oreilles de Chat";
			mes "20 Écailles de Dragon";
			mes "200 Tiges Semblant Faites d'Acier";
			mes "300 Fourrures de Loutre de Mer";
			break;
		case 2:
			mes "[Titicupe]";
			mes "Le Chapeau de Spore? Pour le fabriquer, j'ai besoin de:";
			mes "850 Spores Empoisonnées";
			mes "300 Arbres Calcinés";
			mes "1 Langue";
			break;
		case 3:
			mes "[Titicupe]";
			mes "La Coquille de Noix Laquée? Pour la fabriquer, j'ai besoin de:";
			mes "1 Coquille de Noix";
			mes "500 Ailes de Libellule";
			break;
		case 4:
			mes "[Titicupe]";
			mes "La Coquille Arc-en-Ciel? Pour la fabriquer, j'ai besoin de:";
			mes "1 Coquille d'Oeuf";
			mes "1 Teinture Bleu Cobalt";
			mes "50 Griffes de Loup du Désert";
			break;
		case 5:
			mes "[Titicupe]";
			mes "Des Pommettes?! Pour les fabriquer, j'ai besoin de:";
			mes "100 Tabliers d'Alice";
			break;
		case 6:
			mes "[Titicupe]";
			mes "La Toque? Pour la fabriquer, j'ai besoin de:";
			mes "120 Parts de Gâteau";
			mes "1 Teinture Blanche";
			mes "330 Plumes";
			mes "450 Écailles de Dragon";
			break;
		case 7:
			mes "[Titicupe]";
			mes "Une Bougie Décorative? Pour en fabriquer, j'ai besoin de:";
			mes "1 Mèche";
			mes "50 Allumettes";
			mes "100 Gelées Royales";
			break;
		case 8:
			mes "[Titicupe]";
			mes "Le Gâteau d'Anniversaire? Pour le fabriquer, j'ai besoin de:";
			mes "10 Bonbons";
			mes "5 Sucres d'Orge";
			mes "15 Cookies Cuits à Point";
			mes "20 Parts de Gâteau";
			mes "10 morceaux d'Acier";
			break;
		case 9:
			mes "[Titicupe]";
			mes "Si vous avez besoin d'informations n'hésitez pas. Aucune question n'est embarrassante pour un génie tel que moi!";
		}
		next;
		mes "[Titicupe]";
		mes "Hahaha!!";
		mes "Je suis un génie~!";
		mes "Ho ho ho";
		mes "Ho ho ho ho!";
		close;
	case 3:
		mes "[Titicupe]";
		mes "Parfois j'ai moi-même du mal à y croire... Mes inventions sont si belles...!";
		next;
		mes "[Titicupe]";
		mes "Je...";
		mes "Je crois que je m'aime.";
		Emotion e_kis2;
		next;
		mes "^3355FFTiticupe sautille dans tous les sens en émettant des petits sons d'extase. Il est complètement fou, c'est une évidence.";
		close;
	}
}

xmas,115,297,4	script	Audi	111,{
	mes "[Audi]";
	mes "^555555Automate inventé par le génialissime Titicupe. Veuillez sélectionner le chapeau de votre choix et insérer les objets nécessaires dans le réceptacle prévu à cet effet.^000000";
	next;
	switch(select("^FF3355Notice d'Utilisation^000000:Chapeau de Raton-Laveur:Chapeau de Spore:Coquille de Noix Laquée:Coquille Arc-en-Ciel:Pommettes:Toque:Bougie Décorative:Gâteau d'Anniversaire:Annuler")) {
	case 1:
		mes "[Audi]";
		mes ( isday() ? "Bonjour" : "Bonsoir" ) + "~";
		mes "Je dois vous dire quelque chose d'important. Cet automate n'a pas été conçu pour différencier plusieurs objets similaires.";
		next;
		mes "[Audi]";
		mes "Aussi, si vous portez sur vous un équipement ^FF3355raffiné, ou bien qui possède une carte^000000, et que cet équipement entre dans la composition d'un chapeau, celui-ci pourrait être utilisé et donc perdu!";
		next;
		mes "[Audi]";
		mes "Lorsque vous utilisez l'automate, rangez précieusement vos équipements de valeur dans votre Stock Kafra. Vous éviterez ainsi les mauvaises surprises.";
		next;
		mes "[Audi]";
		mes "Gardez à l'esprit que les chapeaux délivrés par l'automate ne sont ni repris ni échangés.";
		next;
		mes "[Audi]";
		mes "Merci, à bientôt!";
		close;
	case 2:
		if ((countitem(2213) > 0) && (countitem(1036) > 19) && (countitem(7012) > 199) && (countitem(7065) > 299)) {
			mes "^3355FFVous placez délicatement les objets dans la bouche du bonhomme de neige.^000000";
			next;
			delitem 2213,1;  //Cat_Hairband
			delitem 1036,20;  //Dragon_Scale
			delitem 7012,200;  //Tough_Scalelike_Stem
			delitem 7065,300;  //Sea_Otter_Leather
			Emotion e_Oh;
			mes "^3355FF*Vroooooom~~*";
			mes "*Bzzzzzt*";
			mes "*choogachooga*";
			mes "*Kapang!*^000000";
			getitem 5033,1; // Smokie_Hat
			next;
			mes "[Audi]";
			mes "^555555Merci de votre visite.";
			mes "A très bientôt!";
			mes "Oh, et parlez-en à vos amis!^000000";
			close;
		}
		break;
	case 3:
		if ((countitem(7033) > 849) && (countitem(7068) > 299) && (countitem(1015) > 0)) {
			mes "^3355FFVous placez délicatement les objets dans la bouche du bonhomme de neige.^000000";
			next;
			delitem 7033,850;  //Poison_Spore
			delitem 7068,300;  //Burn_Tree
			delitem 1015,1;  //Thin_N'_Long_Tongue
			Emotion e_oh;
			mes "^3355FF*Vroooooom~~*";
			mes "*Bzzzzzt*";
			mes "*choogachooga*";
			mes "*Kapang!*";
			mes "*Wek Wek*^000000";
			getitem 5029,1; // Spore_Hat
			next;
			mes "^555555Merci de votre visite.";
			mes "A très bientôt!";
			mes "Oh, et parlez-en à vos amis!^000000";
			close;
		}
		break;
	case 4:
		if ((countitem(5037) > 0) && (countitem(7064) > 499)) {
			mes "^3355FFVous placez délicatement les objets dans la bouche du bonhomme de neige.^000000";
			next;
			delitem 5037,1;  //Fruit_Shell
			delitem 7064,500;  //Dragon_Fly_Wing
			mes "^3355FF*Vroooooom~~*";
			mes "*Bzzzzzt*";
			mes "*choogachooga*";
			mes "*Kapang!*";
			mes "*BeepBoopBeepBoop*";
			mes "*Beeeeeeoop*^000000";
			Emotion e_oh;
			getitem 5050,1; // Mystery_Fruit_Shell
			next;
			mes "[Audi]";
			mes "^555555Merci de votre visite.";
			mes "A très bientôt!";
			mes "Oh, et parlez-en à vos amis!^000000";
			close;
		}
		break;
	case 5:
		if ((countitem(5015) > 0) && (countitem(978) > 0) && (countitem(7030) > 49)){ 
			mes "^3355FFVous placez délicatement les objets dans la bouche du bonhomme de neige.^000000";
			next;
			delitem 5015,1;  //Egg_Shell
			delitem 978,1;  //Cobaltblue_Dyestuffs
			delitem 7030,50;  //Claw_Of_Desert_Wolf
			Emotion e_oh;
			mes "^3355FF*Vroooooom~~*";
			mes "*Bzzzzzt*";
			mes "*choogachooga*";
			mes "*OoooEeeeeeee~*^000000";
			getitem 5039,1; // Mottled_Egg_Shell
			next;
			mes "[Audi]";
			mes "^555555Merci de votre visite.";
			mes "A très bientôt!";
			mes "Oh, et parlez-en à vos amis!^000000";
			close;
		}
		break;
	case 6:
		if (countitem(7047) > 99) {
			mes "^3355FFVous placez délicatement les 100 Aprons dans la bouche du bonhomme de neige.^000000";
			next;
			delitem 7047,100;  //Alice's_Apron
			Emotion e_oh;
			mes "^3355FF*Vroooooom~~*";
			mes "*Bzzzzzt*";
			mes "*choogachooga*";
			mes "*Kapang!*";
			mes "*ChoopChoop*";
			mes "*Chaaawah!*^000000";
			getitem 5040,1; // Blush
			mes "[Audi]";
			mes "^555555Merci de votre visite.";
			mes "A très bientôt!";
			mes "Oh, et parlez-en à vos amis!^000000";
			next;
			mes "[Titicupe]";
			mes "Vous avez fabriqué des Pommettes?! Hum. Vous essayez d'avoir l'air encore plus glamour~! J'espère que vous vous rendez compte de mon géni à présent, n'est-ce pas?";
			close;
		}
		break;
	case 7:
		if ((countitem(539) > 119) && (countitem(982) > 0) && (countitem(949) > 329) && (countitem(1036) > 449)) {
			mes "^3355FFVous placez délicatement les objets dans la bouche du bonhomme de neige.^000000";
			next;
			delitem 539,120;  //Piece_Of_Cake
			delitem 982,1;  //White_Dyestuffs
			delitem 949,330;  //Feather
			delitem 1036,450;  //Dragon_Scale
			Emotion e_oh;
			mes "^3355FF*Vroooooom~~*";
			mes "*Bzzzzzt*";
			mes "*choogachooga*";
			mes "*Kapang!*";
			mes "*Muuuuuuugeeee*^000000";
			getitem 5026,1; // Hat_Of_Cook
			next;
			mes "[Audi]";
			mes "^555555Merci de votre visite.";
			mes "A très bientôt!";
			mes "Oh, et parlez-en à vos amis!^000000";
			close;
		}
		break;
	case 8:
		if ((countitem(2279) > 0) && (countitem(7035) > 49) && (countitem(526) > 99)) {
			mes "^3355FFVous placez délicatement les objets dans la bouche du bonhomme de neige.^000000";
			next;
			delitem 2279,1;  //Bomb_Wick
			delitem 7035,50;  //Matchstick
			delitem 526,100;  //Royal_Jelly
			Emotion e_oh;
			mes "^3355FF*Vroooooom~~*";
			mes "*Bzzzzzt*";
			mes "*choogachooga*";
			mes "*Kapang!*^000000";
			getitem 5028,1; // Candle
			next;
			mes "[Audi]";
			mes "^555555Merci de votre visite.";
			mes "A très bientôt!";
			mes "Oh, et parlez-en à vos amis!^000000";
			close;
		}
		break;
	case 9:
		if ((countitem(529) > 9) && (countitem(530) > 4) && (countitem(538) > 14) && (countitem(539) > 19) && (countitem(999) > 9)) { 
			mes "^3355FFVous placez délicatement les objets dans la bouche du bonhomme de neige.^000000";
			next;
			delitem 529,10;  //Candy
			delitem 530,5;  //Candy_Striper
			delitem 538,15;  //Well_Baked_Cookie
			delitem 539,20;  //Piece_Of_Cake
			delitem 999,10;  //Steel
			Emotion e_oh;
			mes "^3355FF*Vroooooom~~*";
			mes "*Bzzzzzt*";
			mes "*choogachooga*";
			mes "*Kapang!*^000000";
			getitem 5024,1; // Hat_Of_Cake
			next;
			mes "[Audi]";
			mes "^555555Merci de votre visite.";
			mes "A très bientôt!";
			mes "Oh, et parlez-en à vos amis!^000000";
			close;
		}
		break;
	case 10:
		mes "[Audi]";
		mes "^555555Veuillez...";
		mes "Insérer...";
		mes "Objets.^000000";
		close;
	}
	Emotion e_x;
	mes "[Audi]";
	mes "^555555Erreur Erreur!";
	mes "Objets incorrects!^000000";
	next;
	mes "[Titicupe]";
	mes "Je...";
	mes "Je crois que les gens feraient n'importe quoi pour mettre la main sur des Pommettes.";
	close;
}