//Le Livre d'Ymir http://www.bookofymir.net/
//traduit par Myllena, corrigé par Icaros
//===== eAthena Script =======================================
//= Acolyte Skill Quest
//===== By: ==================================================
//= kobra_k88
//===== Current Version: =====================================
//= 1.5
//===== Compatible With: ===================================== 
//= eAthena SVN
//===== Description: ========================================= 
//= [Aegis Conversion]
//= Quest for skills: Holy Light
//===== Additional Comments: ================================= 
//= 1.5 Rescripted to Aegis 10.3 stadards. [L0ne_W0lf]
//= 1.6 Fixed a typo in job check. (Bugreport:1531) [L0ne_W0lf]
//============================================================

prt_church,173,23,4	script	Acolyte Klift#qsk_al	79,{
	if ( BaseJob != Job_Acolyte && BaseJob != Job_Monk && BaseJob != Job_Priest) { // Bugfix: ils avaient oublié ces checks. [No Healing]
		mes "[Acolyte Klift]";
		mes "Oh, je suis désolée mais je ne suis pas familère avec votre profession. J'ai bien peur que je ne puisse pas grand chose pour vous.";
		close;
	}
	else if (JobLevel < 30 && BaseJob == Job_Acolyte) {
		mes "[Acolyte Klift]";
		mes "Oh, un jeune acolyte! Continuez d'étudier, j'aurai peut-être bientôt quelque chose à vous enseigner.";
		close;
	}
	mes "[Acolyte Klift]";
	if(sex==1) mes "Ahh... Mon Frère!";
	if(sex==0) mes "Ahh... Ma Soeur!";
	mes "Je suis assignée au Sanctuaire afin de venir en aide à mes camarades Prêtres et Acolytes.";
	mes "Je suis fatiguée de devoir sans cesse venir en aide aux brebis égarées, mais je suis ici pour vous assister.";
	next;
	switch(select("^3355FFÀ Propos des Compétences Cachées^000000 ..:Apprendre la ^3355FFLumière Divine^000000:Mettre fin à la conversation")) {
	case 1:
		mes "[Acolyte Klift]";
		mes "Nous autres frères Prêtres et Acolytes sommes souvent confrontés à de grands dangers, dans notre lutte éternelle contre le mal.";
		next;
		mes "[Acolyte Klift]";
		mes "Au cours de leur apprentissage au Clergé, les Acolytes sont amenés à maîtriser leur force intérieure afin d'apprendre une attaque spéciale très utile en combat.";
		next;
		mes "[Acolyte Klift]";
		mes "Cette compétence spéciale se nomme la ^3355FFLumière Divine^000000. Cette attaque est particulièrement efficace contre les morts-vivants!.";
		next;
		mes "[Acolyte Klift]";
		mes "Si vous souhaitez apprendre cette compétence, vous devez me rapporter les objets suivants:";
		mes "^FF33551 Opale^000000";
		mes "^FF33551 Cristal Bleu^000000";
		mes "^FF33551 Rosaire^000000 ";
		next;
		mes "[Acolyte Klift]";
		mes "Vous devez également avoir atteint au moins le ^5555FFNiveau de Métier 30^000000 si vous êtes Acolyte. Cette limite ne s'applique pas si vous êtes déjà Prêtre ou Moine.";
		next;
		mes "[Acolyte Klift]";
		mes "Revenez quand vous aurez rassemblé les objets. Je vous attends ici.";
		close;
	case 2:
		if (getskilllv("AL_HOLYLIGHT") == 1) {
			mes "[Acolyte Klift]";
			if(sex==1) mes "Mon Frère, vous possédez déjà la Lumière Divine.";
			if(sex==0) mes "Ma Soeur, vous possédez déjà la Lumière Divine.";
			mes "Je prie pour que vous utilisiez vos pouvoirs pour le bien...";
			close;
		}
		else {
			if (countitem(727) > 0 && countitem(991) > 0 && countitem(2608) > 0) {
				if ((JobLevel > 29 && BaseJob == Job_Acolyte) || BaseJob == Job_Monk || BaseJob == Job_Priest) {
					mes "[Acolyte Klift]";
					mes "Votre foi a prouvé que vous êtes digne d'acquérir la Lumière Divine. Utilisez vos pouvoirs avec sagesse...";
					next;
					delitem 727,1; //White_Jewel
					delitem 991,1; //Crystal_Blue
					delitem 2608,1; //Rosary
					skill 156,1,0;
					mes "[Acolyte Klift]";
					mes "Je le sens, ça y est... Vous avez réussi à libérer votre force intérieure";
					mes "Vous pouvez maintenant utiliser la ^5555FFLumière Divine^000000! Faites en bon usage.";
					close;
				}
			}
			mes "[Acolyte Klift]";
			mes "Oh, il est clair que... vous n'êtes pas encore prêt à recevoir la Lumière Divine.";
			next;
			mes "[Acolyte Klift]";
			mes "N'oubliez pas d'apporter tous les objets requis. À fortiori, ne négligez pas votre entraînement.";
			close;
		}
	case 3:
		mes "[Acolyte Klift]";
		mes "Je comprends votre zèle. Vous avez encore toute la vie devant vous pour vous entraîner et gagner de l'expérience. Que Dieu vous bénisse...";
		close;
	}
}

//============================================================ 
// Old changelog
//============================================================ 
//= v1.0a Now using functions found in "Global_Functions.txt"
//= for class checks.
//= 1.2 Added Baby Class Support [Lupus]
//= 1.3 Removed callfunc Is_####_Class in favor of baseClass [Silentdragon]
//= 1.4 Fixed an exploit [Lupus]
//= 1.4a changed perm. variables to temp ones [Lupus]
//============================================================