//Le Livre d'Ymir http://www.bookofymir.net/
//traduit par No Healing, corrigé par Myllena
//===== eAthena Script =======================================
//= Thanatos Tower Quest
//===== By: ==================================================
//= [Ishizu-chan]
//===== Current Version: =====================================
//= 2.1
//===== Compatible With: =====================================
//= Any eAthena Version i guess?
//===== Description: =========================================
//= It's the Thanatos Tower Quest...
//===== Additional Comments: =================================
//= 1.0 First Release [Ishizu-chan]
//= 1.1 Updated Thanatos Tower Quest to official. [SinSloth]
//= 1.2 Fixed a bug where Reward NPC didn't give you Zeny and Exp. [SinSloth]
//= 1.3 Added a checking in boss map to reset event if there's no player. [SinSloth]
//= 1.4 Changed the way the Thanatos Portal works to allow people to enter
//= as long as Thanatos is alive. [SinSloth]
//= 1.4a You may enter either "Charmstone" or "Charm Stone" [Lupus]
//= 1.5 Fixed a bug in the number part of the quest. [SinSloth]
//= 1.6 Fixed experience gains to match upcoming rate adjustments. [SinSloth]
//= 1.7 Fixed a minor bug with prevented code part from reseting properly. [SinSloth]
//= 1.8 Corrected NPC names to fall within proper restrictions. [L0ne_W0lf]
//= 1.9 Fixed a bug in the last event which allowed an exploit after the first summoning. [SinSloth]
//= 2.0 Cleaned up the trans-only check, and added expanded classes. [L0ne_W0lf]
//= 2.1 Replaced effect numerics with constants. [Samuray22]
//============================================================

hu_fild01,140,163,5	script	Gardien de la Tour	852,3,3,{

	mes "[Gatei]";
	mes "Salutations, aventurier!";
	mes "Je suis Gatei Knumm, gardien de la Tour de Thanatos.";
	mes "Comment puis-je vous aider?";
	next;
	switch( select( "La Tour de Thanatos?","Prix d'entrée.","Entrer dans la tour.","Annuler." ) )
	{
		case 1:
			mes "[Gatei]";
			mes "Oui, la tour qui se dresse devant vous.";
			mes "Son nom lui vient d'une inscription sur une dalle en pierre trouvée à l'intérieur.";
			mes "Aujourd'hui c'est devenu un lieu touristique très populaire.";
			next;
			mes "[Gatei]";
			mes "Cette tour devient de plus en plus populaire auprès des aventuriers, surtout depuis que la Corporation Rekenber a lancé des travaux de rénovation.";
			mes "Le rez-de-chaussée et le premier étage sont maintenant réhabilités et débarrassés des monstres.";
			next;
			mes "[Gatei]";
			mes "Cependant, la reconstruction des autres étages est toujours inachevée.";
			mes "Les niveaux supérieurs sont toujours infestés de monstres.";
			mes "C'est pourquoi nous recrutons des intérimaires afin de les exterminer.";
			next;
			mes "[Gatei]";
			mes "Si un contrat temporaire vous tente ou si vous voulez plus de détails sur cet endroit, veuillez vous adresser à un guide à l'intérieur.";
			mes "Merci, et profitez de la visite~";
			close;
			
		case 2:
			mes "[Gatei]";
			mes "La Tour de Thanatos peut être visitée par tous.";
			mes "Cependant, seuls le rez-de-chaussée et le premier étage sont ouverts au public à l'heure qu'il est.";
			mes "Le prix d'entrée est de 5000 Zénys par personne.";
			next;
			mes "[Gatei]";
			mes "Le prix peut sembler un peu élevé pour une attraction touristique mais faites-moi confiance, vous ne serez pas prêt d'oublier cette tour.";
			mes "Les visiteurs réguliers ainsi que les travailleurs temporaires peuvent profiter de nos tarifs préférentiels~";
			close;
			
		case 3:
			mes "[Gatei]";
			mes "Voulez-vous entrer dans la Tour de Thanatos?";
			mes "Le prix d'entrée est de ^FF00005000 Zenys^000000.";
			next;
			switch( select( "Entrer.","Une prochaine fois, peut-être." ) )
			{
				case 1:
					if (thana_quest)
					{
						mes "[Gatei]";
						mes "Oh, "+strcharinfo(0)+"!";
						mes "Content de vous revoir!";
						mes "Puisque vous avez un contrat de travail temporaire avec la Corporation Rekenber, le prix d'entrée n'est que de 3000 Zénys.";
						next;
						switch( select( "Entrer.","Non, merci." ) )
						{
							case 1:
								if (Zeny < 3000)
								{
									mes "[Gatei]";
									mes "Oh, je suis désolé mais il semble que vous n'ayez pas assez d'argent.";
									mes "Ce n'est pas dramatique, revenez simplement un peu plus tard~";
									close;
								}
								mes "[Gatei]";
								mes "Merci, et continuez votre excellent travail.";
								mes "Ah, et n'oubliez pas: pensez à votre sécurité en premier lieu quand vous combattez ces monstres!";
								set Zeny,Zeny - 3000;
								close2;
								warp "tha_scene01",131,220;
								end;
								
							case 2:
								mes "[Gatei]";
								mes "Oh, je suis désolé mais il semble que vous n'ayez pas assez d'argent.";
								mes "Ce n'est pas dramatique, revenez simplement un peu plus tard~";
								close;
						}
					}
					if (Zeny < 5000)
					{
						mes "[Gatei]";
						mes "Oh, je suis désolé mais il semble que vous n'ayez pas assez d'argent.";
						mes "Ce n'est pas dramatique, revenez simplement un peu plus tard~";
						close;
					}
					mes "[Gatei]";
					mes "Ah, tout est en règle. Merci.";
					mes "Profitez bien de la visite~";
					set Zeny,Zeny - 5000;
					close2;
					warp "tha_scene01",131,220;
					end;
				
				case 2:
					mes "[Gatei]";
					mes "Comme vous voulez.";
					mes "Revenez quand vous voulez à la Tour de Thanatos!";
					close;
			}
		
		case 4:
			mes "[Gatei]";
			mes "Comme vous voulez.";
			mes "Revenez quand vous voulez à la Tour de Thanatos!";
			close;
	}
}

tha_t01,149,78,4	script	Guide	90,{

	if(!thana_quest)
	{
		mes "[Ditze]";
		mes "Bienvenue à la Tour de Thanatos.";
		mes "La reconstruction de la tour est un projet de la Corporation Rekenber, le rez-de-chaussée et le premier étage sont maintenant ouverts au public.";
		mes "Que puis-je faire pour vous aujourd'hui?";
		next;
		switch( select( "Informations sur la Tour.","Contrat de Travail Temporaire.","Annuler." ) )
		{
			case 1:
				mes "[Ditze]";
				mes "Quand fut construite cette tour, qui l'a construite, et dans quel but, cela reste un mystère.";
				mes "Il y a de nombreuses rumeurs: certains prétendent que ce fut le laboratoire de magiciens, pour d'autres c'était un monument érigé à la gloire d'un héros, et d'autres encore pensent qu'il s'agissait de la forteresse d'un démon...";
				next;
				mes "[Ditze]";
				mes "La Corporation Rekenber a fait des recherches sur les origines de cette tour, mais aucune hypothèse n'a encore été confirmée.";
				mes "Bien que nombre de nos chercheurs aient perdu la vie face aux monstres de la tour, nous n'abandonnons pas!";
				next;
				mes "[Ditze]";
				mes "La Rekenber est convaincue que cette tour renferme maints secrets.";
				mes "Nous avons restauré le rez-de-chaussée et le premier étage, à la recherche de ce savoir perdu.";
				next;
				mes "[Ditze]";
				mes "Nous essayons maintenant de restaurer les étages supérieurs.";
				mes "Fort heureusement, de nombreux aventuriers embauchés comme intérimaires exterminent les monstres de ces étages.";
				next;
				mes "[Ditze]";
				mes "Si nous continuons à ce rythme, leur restauration sera achevée dans un futur proche, nous rapprochant de notre but final: ouvrir au public les 12 étages de la Tour de Thanatos.";
				next;
L_Ask1:
				switch( select( "Les Monstres?","Contrat de Travail Temporaire?","......" ) )
				{
					case 1:
						mes "[Ditze]";
						mes "Oui, lorsque nous commençâmes la reconstruction de la Tour de Thanatos, des monstres ressemblant à des anges apparurent de nulle part et se mirent à attaquer nos employés.";
						next;
						mes "[Ditze]";
						mes "Au début, les témoins pensèrent qu'ils auraient pu être, vous savez... de véritables anges.";
						mes "Mais si ça avait été le cas, pourquoi auraient-ils attaqué sans raison?";
						next;
						mes "[Ditze]";
						mes "Quoi qu'il en soit, nous avons mandaté l'Académie des Sages de Yuno pour enquêter sur ce phénomène, et ils ont confirmé que ce sont de véritables monstres: leur ressemblance avec des anges n'est que fortuite.";
						next;
						goto L_Ask1;

					case 2:
						break;
												
					case 3:
						mes "[Ditze]";
						mes "Afin de pouvoir travailler sur les étages au-delà du second, nous allons avoir besoin d'autant de travailleurs temporaires que possible.";
						mes "Pourquoi ne travailleriez-vous pas avec nous en tant qu'intérimaire? Pensez-y!";
						close;
				}
				break;
				
			case 2:
				break;
				
			case 3:
				mes "[Ditze]";
				mes "Eh bien, n'hésitez pas à revenir me voir quand vous aurez d'autres questions.";
				mes "Je m'appelle Ditze Lappa. Bonne "+ ( isday() ? "journée" : "soirée" ) +"!";
				close;
		}
		mes "[Ditze]";
		mes "Le Gardien de la Tour vous en a peut-être déjà parlé: nous recrutons des aventuriers en tant qu'intérimaires pour exterminer les monstres de la tour à partir du second étage.";
		next;
		mes "[Ditze]";
		mes "Je suis responsable de l'embauche des travailleurs temporaires, donc nous pouvons en parler si cela vous intéresse.";
		mes "Seuls les travailleurs intérimaires sont autorisés à accéder aux étages supérieurs de la Tour de Thanatos.";
		next;
		switch( select( "La prochaine fois, peut-être.","Bien sûr, je voudrais travailler pour vous." ) )
		{
			case 1:
				mes "[Ditze]";
				mes "Très bien. Revenez me voir si vous décidez d'aider la Rekenber pour la reconstruction.";
				close;
									
			case 2:
				mes "[Ditze]";
				mes "Fantastique!";
				mes "Je vais d'abord vous demander de remplir ce formulaire d'embauche.";
				mes "Voyons. Vous vous appelez... "+strcharinfo(0)+", c'est cela?";
				next;
				switch( select( "Oui." ) )
				{
					case 1:
						break;
				}
				mes "[Ditze]";
				mes "D'accord. Veuillez lire ce contrat avec attention.";
				mes "Si vous en acceptez toutes les clauses, apposez votre signature en bas de page.";
				next;
				mes "^3355FFDitze vous tend un document intitulé 'Contrat de Travail' pour que vous le lisiez.^000000";
				next;
				mes "- Contrat de Travail -";
				mes " ";
				mes "1. Ce contrat de travail lie la Corporation Rekenber (Employeur) à "+strcharinfo(0)+" (Employé).";
				mes "1-1. Ce contrat de travail établit un contrat de type 'Mercenariat' entre les deux parties.";
				mes "2. Les termes de ce contrat prendront effet immédiatement après sa signature par les deux parties (employeur et employé).";
				mes "3. L'employé s'engage à apporter une preuve matérielle attestant de son travail lorsque l'employeur lui confie une mission.";
				mes "3-1. Veuillez vous référer à la section 7A pour des exemples de preuves acceptables de l'extermination de monstres.";
				mes "3-2. Seul l'employeur, ou un représentant de l'employeur, est juge de l'acceptabilité ou non des preuves présentées.";
				mes "4. L'employeur s'engage à payer un salaire compensatoire sous forme de récompense à l'employé après avoir reçu une des preuves susmentionnées.";
				mes "4-1. Les récompenses suivantes peuvent être données suite à l'éradication des monstres:";
				mes ".................................................";
				mes ".................................................";
				mes ".................................................";
				mes ".................................................";
				mes ".................................................";
				mes "13. Les termes de ce contrat ne s'appliquent qu'à l'intérieur de la Tour de Thanatos.";
				mes "14. Les employés recevront une réduction sur le prix d'entrée de la Tour de Thanatos.";
				mes " ";
				mes " ";
				mes " ";
				mes "Signature de l'Employeur__________";
				mes "Signature de l'Employé____________";
				next;
				switch( select( "Signer.","Ne pas Signer." ) )
				{
					case 1:
						mes "^3355FFVous signez deux exemplaires du Contrat de Travail.^000000";
						next;
						mes "[Ditze]";
						mes "Merci. Vous être désormais officiellement un employé de la Corporation Rekenber!";
						mes "Dans l'enceinte de cette tour tout du moins: ce contrat ne s'applique pas en dehors.";
						next;
						mes "[Ditze]";
						mes "Vous pouvez maintenant parler au Guide du premier étage pour entrer dans les étages supérieurs.";
						mes "Veuillez vous adresser à ^3355FFLiei^000000 si vous avez des questions à propos des récompenses.";
						next;
						mes "[Ditze]";
						mes "Toute question à propos de votre travail devra être adressée au Guide du premier étage.";
						mes "Merci, et bienvenue dans la Corporation Rekenber~";
						set thana_quest,1;
						close;
									
					case 2:
						mes "[Ditze]";
						mes "Oh? Il y a un article avec lequel vous êtes en désaccord?";
						mes "C'est comme vous voulez. Mais revenez me voir à tout moment si vous changez d'avis.";
						mes "Merci~";
						close;
				}
		}
	}
	mes "[Ditze]";
	mes "Pour plus de détails à propos de l'extermination des monstres, veuillez vous adresser au guide du premier étage, ainsi qu'à mon collègue ici présent.";
	mes "Nous espérons que vous appréciez de travailler pour la Corporation Rekenber~";
	close;
}

tha_t01,140,78,4	script	Guide#thana	831,{

	if(!thana_quest)
	{
		mes "[Liei]";
		mes "Bien le " + ( isday() ? "bonjour" : "bonsoir" ) + "!";
		mes "Je suis Liei Kuniziet du Département des Récompenses pour nos employés ici, à la Tour de Thanatos.";
		next;
		switch( select( "Récompenses pour les employés?","Continuez de faire du bon travail." ) )
		{
			case 1:
				mes "[Liei]";
				mes "La Corporation Rekenber recrute des intérimaires afin d'ouvrir les étages supérieurs de la tour.";
				mes "Si vous voulez travailler pour nous, je vous suggère de parler à Ditze ici présente.";
				close;
				
			case 2:
				mes "[Liei]";
				mes "Merci. Ah, j'espère que vous appréciez la visite de la Tour~";
				close;
		}
	}
	mes "[Liei]";
	mes "Bien le " + ( isday() ? "bonjour" : "bonsoir" ) + "~";
	mes "Est-ce que je peux vous aider?";
	next;
	switch( select( "Je viens chercher ma récompense.","Non, merci." ) )
	{
		case 1:
			mes "[Liei]";
			mes "Vous êtes "+strcharinfo(0)+", c'est ça? Attendez, je vérifie juste... ah! Voilà!";
			mes "D'accord. Pouvez-vous me dire quelle sorte d'objets vous m'apportez afin de prouver que vous avez mené à bien votre mission?";
			next;
			switch( select( "Bijou Doré","Plume Rouge","Plume Bleue","Sceau Maudit" ) )
			{
				case 1:
					callfunc "Func_Thana",7435;
				
				case 2:
					callfunc "Func_Thana",7440;
					
				case 3:
					callfunc "Func_Thana",7441;
				
				case 4:
					callfunc "Func_Thana",7442;
			}
			
		case 2:
			mes "[Liei]";
			mes "D'accord. Essayez de faire de votre mieux pour exterminer les monstres qui grouillent dans les étages supérieurs de la Tour~";
			close;
	}
}
		
function	script	Func_Thana	{

	if(!countitem(getarg(0)))
	{
		mes "[Liei]";
		mes "Oh, je suis désolé mais vous n'avez aucun "+ getitemname(getarg(0)) +"";
		mes "Vous devriez vérifier votre inventaire à nouveau...";
		close;
	}
	mes "[Liei]";
	mes "La récompense pour chaque "+ getitemname(getarg(0)) +" est de...";
	mes " ";
	mes "1000 Zénys et";
	mes "2000 Points d'Expérience.";
	next;
	mes "[Liei]";
	mes "En me donnant vos "+ countitem(getarg(0)) +" "+ getitemname(getarg(0)) +", vous recevrez un total de...";
	mes " ";
	mes ""+ countitem(getarg(0)) * 1000 +" Zénys et";
	mes ""+ countitem(getarg(0)) * 2000 +" Points d'Expérience.";
	next;
	mes "[Liei]";
	mes "Voulez-vous me donner tous vos "+ getitemname(getarg(0)) +" et obtenir votre récompense maintenant?";
	next;
	switch( select( "Oui","Non" ) )
	{
		case 1:
			mes "[Liei]";
			mes "Très bien! Voici vos "+ countitem(getarg(0)) * 1000 +" Zénys et vos "+ countitem(getarg(0)) * 2000 +" Points d'Expérience.";
			mes "Merci, et continuez de faire du bon travail~";
			set Zeny,Zeny + countitem(getarg(0)) * 1000;
			getexp countitem(getarg(0))*2000,0;
			delitem getarg(0),countitem(getarg(0));
			close;
			
		case 2:
			mes "[Liei]";
			mes "Aucun problème. Revenez simplement me voir quand vous voudrez recevoir votre récompense, d'accord?";
			close;
	}
}

tha_t02,231,161,5	script	Guide du Second Étage::Guide du 2ème Étage	874,{

	if(!thana_quest)
	{
		mes "[Burled]";
		mes "Vous vous trouvez à l'entrée du second étage.";
		mes "Seuls les travailleurs temporaires sont autorisés à pénétrer dans cette zone.";
		mes "Veuillez vous adresser au Guide du premier étage si vous désirez en savoir plus sur les contrats intérimaires de la Rekenber.";
		close;
	}
	mes "[Burled]";
	mes "......";
	mes ".........";
	mes "............";
	next;
	switch( select( "Excusez-moi...","........." ) )
	{
		case 1:
			mes "[Burled]";
			mes "Oh...";
			mes "Désolé. En quoi puis-je vous aider?";
			next;
			if(thana_quest < 2)
			{
				switch( select( "Monter au second étage.","Informations sur le passage." ) )
				{
					case 1:
L_Access3:
						mes "[Burled]";
						mes "Oh, d'accord. Laissez-moi regarder... Ah oui je vois votre nom sur la liste des employés.";
						mes "Vous êtes "+strcharinfo(0)+", c'est ça?";
						set .@thana_level2,getareausers("tha_t02",226,156,236,166);
						next;
						if(.@thana_level2 < 5)
						{
							mes "[Burled]";
							mes "Mais d'abord il va falloir attendre qu'au moins 5 intérimaires se soient rassemblés pour former un groupe de travail.";
							mes "Pour le moment nous avons "+ .@thana_level2 +" intérimaires en attente de monter au second étage.";
							next;
							mes "[Burled]";
							mes "Si vous le pouvez, essayez de rassembler vos amis et venez ici, là où je peux vous voir.";
							mes "Comprenez bien que nous organisons ces groupes pour des raisons de sécurité.";
							close;
						}
						mes "[Burled]";
						mes "Ah, vous arrivez au bon moment!";
						mes "Nous venons d'atteindre la limite de 5 personnes, donc nous allons bientôt ouvrir la porte vers le second étage.";
						next;
						mes "[Burled]";
						mes "La porte du second étage ne restera ouverte que très peu de temps, donc franchissez-la dès que vous le pouvez.";
						mes "Nous devrons la refermer rapidement: nous ne pouvons pas laisser les monstres pénétrer dans les étages inférieurs.";
						close2;
						donpcevent "#thana3::OnOpen";
						end;
					
					case 2:
L_GateInfo:
						mes "[Burled]";
						mes "Cette porte est le seul passage vers le second étage.";
						mes "Passé le troisième étage, les passages entre chaque niveau ne sont que dans un sens, ce qui veut dire que vous ne pourrez plus rebrousser chemin.";
						next;
						mes "[Burled]";
						mes "Vous savez, un pouvoir étrange affecte les étages au-delà du troisième. Il perturbe les sens des gens qui s'y rendent et ceux-ci ne peuvent plus retrouver le chemin par lequel ils sont venus.";
						next;
						mes "[Burled]";
						mes "Donc si vous montez au-delà du troisième étage, faites bien attention et assurez-vous que vous trouverez un moyen de revenir en arrière.";
						mes "De plus, les monstres se font de plus en plus puissants à mesure que vous progressez dans les étages supérieurs...";
						next;
						mes "[Burled]";
						mes "À cause de la dangerosité des niveaux supérieurs, nous n'ouvrons la porte du second étage que lorsque au moins 5 employés ont formé une équipe.";
						close;
				}
			}
			switch( select( "Monter au second étage.","Informations sur le passage.","A propos de Satan Morroc..." ) )
			{
				case 1:
					goto L_Access3;
					
				case 2:
					goto L_GateInfo;
				
				case 3:
					mes "[Burled]";
					mes "Satan Morroc...?";
					mes "Hummm... Parler de ça est plus ou moins tabou, non?";
					mes "Je veux dire... Le simple fait de prononcer son nom provoque de vives réactions: les gens se fâchent ou prennent peur, vous savez?";
					next;
					switch( select( "Je veux vraiment en savoir plus.","Désolé, je ne savais pas..." ) )
					{
						case 1:
							mes "[Burled]";
							mes "Quand la Corporation Rekenber a commencé la restauration de la Tour de Thanatos, la Cool Event Corp. était notre principal partenaire commercial dans notre projet de reconstruction.";
							next;
							mes "[Burled]";
							mes "Oui, je me souviens que la Cool Event Corp. a investi une quantité astronomique de zénys et de main d'oeuvre pour reconstruire la tour et renforcer leurs relations commerciales avec la Corporation Rekenber...";
							next;
							mes "[Burled]";
							mes "Puis il y eut une sorte d'accident.";
							mes "Une explosion se produisit dans les étages supérieurs de la Tour de Thanatos.";
							mes "Quelques-uns pensent qu'il aurait pu s'agir de Satan Morroc, mais je n'en suis pas si sûr.";
							next;
							mes "[Burled]";
							mes "À cause de cette explosion, la Cool Event Corp. reprit ses investissements dans le projet de reconstruction.";
							mes "Ils abandonnèrent littéralement la Corporation Rekenber.";
							next;
							mes "[Burled]";
							mes "Mais bon...";
							mes "Peu après cet évènement, la Corporation Rekenber racheta la Cool Event Corp.";
							mes "Je veux dire... la compagnie garde son nom mais c'est maintenant une branche de la Rekenber.";
							next;
							mes "[Burled]";
							mes "Je sais, je sais...";
							mes "Tout cela semble étrangement suspect. Mais s'il vous plaît, rendez-moi un service: ne dites à personne que je vous ai parlé de cette rumeur, d'accord?";
							close;

						case 2:
							close;
					}
			}
		
		case 2:
			mes "["+strcharinfo(0)+"]";
			mes ".............";
			close;
	}
}

tha_t02,227,163,1	script	#thana3	45,1,1,{

OnInit:
	disablenpc "#thana3";
	end;

OnTouch:
	if(!thana_quest) warp "tha_t02",227,158;
	else warp "tha_t03",219,159;
	end;
	
OnOpen:
	enablenpc "#thana3";
	initnpctimer;
	end;
	
OnTimer30000:
	stopnpctimer;
	disablenpc "#thana3";
	end;
}

tha_t03,67,70,0	script	Machine#thana1	111,{

	if((countitem(7421)) || (countitem(7426)))
	{
		mes "^3355FFIl s'agit d'une machine très particulière qui émet un étrange bourdonnement.";
		mes "En y regardant de plus près, vous pouvez entrevoir une barrière d'énergie qui l'entoure.^000000";
		close;
	}
	mes "^3355FFUn champ d'énergie mystérieux entoure la machine et son pouvoir vous empêche d'approcher.^000000";
	next;
	switch( select( "Frapper le champ d'énergie.","S'écarter." ) )
	{
		case 1:
			if (getequipweaponlv(4) < 4)
			{
				mes "^3355FFVous frappez le champ d'énergie avec votre arme de toutes vos forces mais vous ne pouvez briser la barrière.";
				mes "Vous avez sans doute besoin d'une arme plus puissante...^000000";
				close;
			}
			mes "^3355FFArmé de votre "+getequipname(4)+", vous frappez le champ d'énergie de toutes vos forces.";
			mes "Après avoir absorbé l'impact, le champ se disperse en faisant un petit bruit: 'pzzzzzh'~^000000";
			next;
			switch( select( "Inspecter la machine.","S'écarter." ) )
			{
				case 1:
					mes "^3355FFAlors que vous examinez le mécanisme, vous pressez accidentellement un bouton, déclenchant une série de bips suivie de la mise en marche de l'écran de contrôle.^000000";
					next;
					switch( select( "Lire ce qu'il y a sur l'écran.","Ignorer l'écran." ) )
					{
						case 1:
							mes "^426F42J'ai utilisé la technologie pour sceller les portes et les pierres enchantées. Bien que les seaux soient en place, je ne peux m'empêcher de craindre qu'ils ne finissent par se briser.^000000";
							next;
							mes "^426F42Je ne peux pas me détendre quand je pense à - devrais-je le dire? - ceux qui convoitent les pierres enchantées et qui peuvent facilement briser les seaux.";
							mes "Afin de les en dissuader, j'ai changé la destination des Portails avant de les sceller.^000000";
							next;
							mes "^426F42Je n'ai pas vérifié les coordonnées exactes de destination, mais j'ai un sentiment doux et apaisant qui me fait dire qu'il ne s'agit pas de l'Enfer.^000000";
							next;
							mes "^3355FFVous avez fini de lire le texte affiché à l'écran.";
							mes "À en juger par son contenu, il y avait probablement d'autres passages avant et après le texte affiché.^000000";
							next;
							switch( select( "Continuer à examiner la machine.","Arrêter de chercher." ) )
							{
								case 1:
									mes "^3355FFVous trouvez une petite clé sur un coin de la machine.";
									mes "Le simple fait de la toucher vous donne un étrange sentiment.^000000";
									getitem 7421,1;
									close;
									
								case 2:
									break;
							}
							break;
							
						case 2:
							mes "^3355FFVous décidez d'ignorer le texte affiché et découvrez immédiatement une petite clé posée sur un coin de la machine.";
							mes "Le simple fait de la toucher vous donne un étrange sentiment.^000000";
							getitem 7421,1;
							close;
					}
					break;
					
				case 2:
					mes "^3355FFVous décidez de vous écarter de la machine.^000000";
					close;
			}
			break;
		
		case 2:
			break;
	}
	mes "^3355FFVous décidez de vous écarter de la machine.^000000";
	close;
}

tha_t04,195,195,0	script	Machine#thana2	111,{

	if((countitem(7422)) || (countitem(7427)))
	{
		mes "^3355FFCe mécanisme n'est pas activé, et n'est pas en marche.";
		mes "Cependant, vous avez dans l'idée qu'il pourra vous servir plus tard...^000000";
		close;
	}
	mes "^3355FFVous trouvez un pavé numérique sous l'écran de contrôle.";
	mes "Tandis que vous appuyez sur l'une des touches, vous entendez un bip et l'écran se met en marche.^000000";
	next;
	mes "[Écran]";
	mes "Veuillez entrer un nombre à 3 chiffres.";
	mes "Chaque chiffre ne doit être utilisé qu'une seule fois, et vous ne pouvez utiliser le chiffre 0.";
	next;
	if(@thanatry) goto L_Input;
L_Recode:
	set @thanacode1,rand(1,9);
	set @thanacode2,rand(1,9);
	set @thanacode3,rand(1,9);
	if((@thanacode1 == @thanacode2) || (@thanacode1 == @thanacode3) || (@thanacode2 == @thanacode3)) goto L_Recode;
L_Input:
	input @thanainput;
	if((@thanainput < 100) || (@thanainput > 999))
	{
		mes "[Écran]";
		mes "Erreur système!";
		mes "Veuillez entrer un nombre à 3 chiffres.";
		close;
	}
	set @thanainput1,@thanainput / 100;
	set @thanainput2,(@thanainput % 100) / 10;
	set @thanainput3,@thanainput % 10;
	if ((@thanainput1 == 0) || (@thanainput2 == 0) || (@thanainput3 == 0))
	{
		mes "[Écran]";
		mes "Tentative de piratage détectée!";
		mes "Vous ne pouvez utiliser le chiffre 0 ou entrer deux fois le même chiffre.";
		next;
		goto L_Input;
	}
	mes "[Écran]";
	mes "Vous avez entré...";
	mes "^0000ff"+@thanainput1+"^000000, ^0000ff"+@thanainput2+"^000000, ^0000ff"+@thanainput3+"^000000";
	mes " ";
	mes "Vérification en cours...";
	mes "Veuillez patienter...";
	set @thanatry,@thanatry +1;
	next;
	set @strike,0;
	set @ball,0;
	if(@thanainput1 == @thanacode1) set @strike,@strike +1;
	if(@thanainput2 == @thanacode2) set @strike,@strike +1;
	if(@thanainput3 == @thanacode3) set @strike,@strike +1;
	if((@thanainput1 == @thanacode2) || (@thanainput1 == @thanacode3)) set @ball,@ball +1;
	if((@thanainput2 == @thanacode1) || (@thanainput2 == @thanacode3)) set @ball,@ball +1;
	if((@thanainput3 == @thanacode1) || (@thanainput3 == @thanacode2)) set @ball,@ball +1;
	if(@strike == 3)
	{
		mes "[Écran]";
		mes "Code bon.";
		mes "Authentification réussie.";
		set @thanatry,0;
		next;
		mes "^3355FFAprès que le message de confirmation se soit affiché, un nouveau texte apparaît sur la console, et un compartiment s'ouvre sous l'écran.^000000";
		next;
		switch( select( "Lire le texte à l'écran.","Examiner le compartiment.","Annuler." ) )
		{
			case 1:
				mes "[Sauvegarde]";
				mes "^426F42Cela ne peut vouloir dire qu'une chose: elle est venue ici pour Satan Morroc.";
				mes "Après avoir examiné la zone, j'ai trouvé des traces d'une bataille entre des créatures de taille humaine et un monstre gigantesque.^000000";
				next;
				mes "[Sauvegarde]";
				mes "^426F42Je devine que son groupe a bel et bien livré bataille avec Satan Morroc et a réussi à le blesser grièvement.";
				mes "Il semble que Satan Morroc ait battu en retraite vers le sud et que son groupe l'ait suivi.^000000";
				next;
				mes "[Sauvegarde]";
				mes "^426F42Etrangement je n'ai trouvé aucune trace d'elle, ce qui est d'autant plus étrange quand on sait que les vestiges dans cette zone sont restés intacts pendant des siècles.";
				mes "Mais je n'arrive pas à comprendre pourquoi...^000000";
				next;
				mes "^3355FFVous avez terminé de lire les sauvegardes.^000000";
				next;
				switch( select( "Examiner le compartiment.","Annuler." ) )
				{
					case 1:
						break;
						
					case 2:
						close;
				}
			
			case 2:
				mes "^3355FFVous trouvez une petite clé brillante dans un coin du compartiment.";
				mes "Le simple fait de l'avoir dans la main vous procure une sensation étrange.^000000";
				if(thana_quest == 1) set thana_quest,2;
				getitem 7422,1;
				close;
				
			case 3:
				mes "^3355FFAprès un court moment, vous entendez un petit bip sonore.";
				mes "Le texte à l'écran disparaît et le compartiment sous l'écran se rétracte pour se fermer.^000000";
				close;
		}
	}
	mes "[Écran]";
	mes "*Biiiiip*";
	mes "Erreur! Séquence numérique non autorisée.";
	next;
	mes "[Écran]";
	mes "Nombre exact";
	mes "Dans l'ordre exact";
	mes "Chiffres corrects dans la séquence: ^FF0000"+@strike+"^000000";
	mes " ";
	mes "Chiffres mal placés dans la séquence: ^FF0000"+@ball+"^000000";
	next;
	if(@thanatry > 4)
	{
		mes "[Écran]";
		mes "Nombre correct";
		mes "La séquence d'authentification était...";
		mes "^ff0000"+@thanacode1+"^000000, ^ff0000"+@thanacode2+"^000000, ^ff0000"+@thanacode3+"^000000";
		mes "Le numéro d'accès changera à chaque nouvelle tentative.";
		set @thanatry,0;
		close;
	}
	goto L_Input;
}

tha_t05,101,37,0	script	Machine#thana3	111,{

	if((countitem(7423)) || (countitem(7428)))
	{
		mes "^3355FFVous ne trouvez rien ici, en dehors de marques presque effacées sur le sol.^000000";
		close;
	}
	set .@thana_level5,getareausers("tha_t05",98,34,104,40);
	if(!.@thana_level5)
	{
		mes "^3355FFVous êtes inexplicablement attiré vers la machine.";
		mes "Il n'y a qu'un écran bleu au centre: nul bouton ni interrupteur.^000000";
		if(rand(1,3) == 2)
		{
			next;
			mes "^3355FFVous apercevez une notice en bas de l'écran qui dit:";
			mes "'Le fonctionnement de cette machine requiert la présence d'au moins quatre membres du personnel, identifiés au moyen du système de détection sensible à la pression.'^000000";
			close;
		}
		close;
	}
	else if(.@thana_level5 < 4)
	{
		mes "^3355FFVous êtes inexplicablement attiré vers cette machine.";
		mes "Il n'y a qu'un écran bleu au centre: nul bouton ni interrupteur.^000000";
		next;
		mes "^3355FFVous examinez attentivement les alentours et remarquez une plaque reluisante au sol, près de la machine.^000000";
		close;
	}
	else
	{
		mes "^3355FFVous vous approchez de la machine et le sol autour commence à briller.";
		mes "Un texte apparaît à l'écran, et le compartiment sous le moniteur s'ouvre.^000000";
		next;
		switch( select( "Lire le texte à l'écran.","Examiner le compartiment.","Annuler." ) )
		{
			case 1:
				mes "[Sauvegarde]";
				mes "^426F42Après toutes ces épreuves, j'ai décidé de partir. Mais avant que je ne puisse le faire, j'ai dû sceller le Portail qui mène à cet endroit.^000000";
				next;
				mes "[Sauvegarde]";
				mes "^426F42Si quelqu'un venait à découvrir cette tour et empruntait le Portail à des fins maléfiques, le monde souffrirait d'une nouvelle ère de chaos.";
				mes "Bien sûr, je sais qu'ils m'arrêteraient s'ils savaient que je suis en train de sceller le Portail...^000000";
				next;
				mes "[Sauvegarde]";
				mes "^426F42Cela m'a pris un temps incroyable mais j'ai réussi à sceller secrètement le Portail.";
				mes "Mais avant que je ne commence mon oeuvre, j'avais décidé de l'examiner plus en détails, à tout hasard.^000000";
				next;
				mes "[Sauvegarde]";
				mes "^426F42Mes observations ont révélé que le Portail tire son énergie des Pierres Enchantées.";
				mes "Afin d'empêcher quiconque d'abuser de son pouvoir, j'ai scellé les Pierres dans des endroits distincts...^000000";
				next;
				mes "^3355FFVous avez terminé de lire le texte affiché à l'écran.^000000";
				close;
				
			case 2:
				mes "^3355FFVous trouvez une petite clé brillante à l'intérieur du compartiment sous l'écran de contrôle.^000000";
				getitem 7423,1;
				close;
				
			case 3:
				close;
		}
	}
}

tha_t06,43,152,0	script	Machine#thana4	111,{

	if((countitem(7424)) || (countitem(7429)))
	{
		mes "^3355FFVous trouvez un mécanisme désactivé avec une série de rouages intéressants.^000000";
		close;
	}
	mes "^3355FFVous trouvez un mécanisme avec une quantité impressionnante de rouages.";
	mes "Un écran noir est fixé sur le côté de la machine.^000000";
	next;
	switch( select( "L'examiner.","Annuler." ) )
	{
		case 1:
			if((countitem(7421)) || (countitem(7422)) || (countitem(7423)))
			{
				mes "^3355FFAlors que vous examinez les rouages, ils semblent réagir à la clé que vous avez sur vous en émettant de légers bruits très étranges.";
				mes "Après quelques instants, ceux-ci s'arrêtent et la machine redevient silencieuse.^000000";
				next;
				switch( select( "Examiner le châssis de la machine.","Examiner les rouages.","Annuler." ) )
				{
					case 1:
						mes "^3355FFLa clé que vous avez sur vous ne semble pas faire réagir le châssis.";
						mes "L'écran fixé sur le côté est toujours noir et désactivé.^000000";
						close;
						
					case 2:
						set @thana_small1,0;
						set @thana_small2,0;
						set @thana_big1,0;
						set @thana_big2,0;
						set @thana_big3,0;
						mes "^3355FFVous posez la main sur l'un des rouages et vous vous apercevez qu'il bouge de façon presque imperceptible.";
						mes "Vous remarquez qu'il y a deux petits rouages, et trois autres beaucoup plus gros, pour un total de cinq rouages sur cette machine.^000000";
						next;
						mes "^3355FFLes plus gros rouages tournent verticalement, déclenchant le mouvement des deux plus petits.^000000";
						next;
						mes "^3355FFA en juger par les vibrations de la machine et par ses petits bruits saccadés, vous pensez pouvoir être en mesure de remettre la machine en marche en alignant les rouages.^000000";
L_Wheels:
						next;
						mes "^3355FFQuel rouage voulez-vous déplacer?^000000";
						switch( select( "1er petit rouage","2nd petit rouage","1er grand rouage","2nd grand rouage","3ème grand rouage","Voir la position actuelle des rouages","Remettre les rouages à leur place d'origine" ) )
						{
							case 1:
								set @wheelresult,callfunc("Thana_Wheels","Déplacer le rouage de côté",@thana_small1,2,1,3);
								if(@wheelresult == 1) break;
								goto L_Wheels;
								
							case 2:
								set @wheelresult,callfunc("Thana_Wheels","Déplacer le rouage de côté",@thana_small2,3,2,1);
								if(@wheelresult == 1) break;
								goto L_Wheels;
								
							case 3:
								set @wheelresult,callfunc("Thana_Wheels","Déplacer verticalement le rouage",@thana_big1,1,3,2);
								if(@wheelresult == 1) break;
								goto L_Wheels;
										
							case 4:
								set @wheelresult,callfunc("Thana_Wheels","Déplacer verticalement le rouage",@thana_big2,2,3,1);
								if(@wheelresult == 1) break;
								goto L_Wheels;
										
							case 5:
								set @wheelresult,callfunc("Thana_Wheels","Déplacer verticalement le rouage",@thana_big3,2,1,3);
								if(@wheelresult == 1) break;
								goto L_Wheels;
										
							case 6:
								if(@thana_small1 == 0) mes "1er petit rouage: Aucun changement";
								else if(@thana_small1 == 1) mes "1er petit rouage: En bas";
								else if(@thana_small1 == 2) mes "1er petit rouage: En haut";
								else if(@thana_small1 == 3) mes "1er petit rouage: Déplacé de côté";
								if(@thana_small2 == 0) mes "2nd petit rouage: Aucun changement";
								else if(@thana_small2 == 1) mes "2ème petit rouage: Déplacé de côté";
								else if(@thana_small2 == 2) mes "2ème petit rouage: En bas";
								else if(@thana_small2 == 3) mes "2ème petit rouage: En haut";
								if(@thana_big1 == 0) mes "1er grand rouage: Aucun changement";
								else if(@thana_big1 == 1) mes "1er grand rouage: En haut";
								else if(@thana_big1 == 2) mes "1er grand rouage: Déplacé de côté";
								else if(@thana_big1 == 3) mes "1er grand rouage: En bas";
								if(@thana_big2 == 0) mes "2nd grand rouage: Aucun changement";
								else if(@thana_big2 == 1) mes "2ème grand rouage: Déplacé de côté";
								else if(@thana_big2 == 2) mes "2ème grand rouage: En haut";
								else if(@thana_big2 == 3) mes "2ème grand rouage: En bas";
								if(@thana_big3 == 0) mes "3ème grand rouage: Aucun changement";
								else if(@thana_big3 == 1) mes "3ème grand rouage: En bas";
								else if(@thana_big3 == 2) mes "3ème grand rouage: En haut";
								else if(@thana_big3 == 3) mes "3ème grand rouage: Déplacé de côté";
								goto L_Wheels;
									
							case 7:
								set @thana_small1,0;
								set @thana_small2,0;
								set @thana_big1,0;
								set @thana_big2,0;
								set @thana_big3,0;
								goto L_Wheels;
						}
						next;
						mes "^3355FFAlors que vous êtes en train d'ajuster les rouages, ils s'immobilisent et émettent un clic net.";
						mes "L'écran s'active alors et affiche un messages tandis que le compartiment en dessous s'ouvre.^000000";
						next;
						switch( select( "Lire le texte affiché à l'écran.","Examiner le compartiment sous le moniteur.","Annuler." ) )
						{
							case 1:
								mes "[Sauvegarde]";
								mes "^426F42Cette tour n'est née ni de la main des hommes ni de celle des dieux: elle est l'oeuvre des démons.";
								mes "Intrigué par cette information, j'ai tenté d'en apprendre plus sur leurs desseins lorsqu'ils construisirent la Tour de Thanatos.^000000";
								next;
								mes "[Sauvegarde]";
								mes "^426F42Pendant mes recherches, j'ai appris que cette tour servait de portail vers les enfers pour invoquer des démons durant la Guerre de Mille Ans, et que le tristement célèbre Satan Morroc fut l'un de ceux qui franchirent ce portail.^000000";
								next;
								mes "[Sauvegarde]";
								mes "^426F42Satan Morroc... J'admets que je serais curieux d'en apprendre plus à propos de son apparition.";
								mes "Il semble que cela corresponde à la période où *elle* arriva à la Tour de Thanatos...^000000";
								next;
								mes "^3355FFVous avez terminé de lire le texte affiché à l'écran.^000000";
								close;
									
							case 2:
								mes "^3355FFVous trouvez une petite clé brillante à l'intérieur du compartiment et vous décidez de la prendre.^000000";
								getitem 7424,1;
								close;
										
							case 3:
								break;
						}
						break;
						
					case 3:
						break;
				}
			}
			else
			{
				mes "^3355FFCette machine est activée, comme le prouvent ses rouages en mouvement.^000000";
				close;
			}
			
		case 2:
			mes "^3355FFVous ne trouvez rien à examiner: tout semble normal et en place...^000000";
			close;
	}
			
}

function	script	Thana_Wheels	{

	switch( select( "Lever le rouage d'un cran.","Baisser le rouage d'un cran.",getarg(0) ) )
	{
		case 1:
			set getarg(1),getarg(2);
			if((@thana_small1 == getarg(2)) && (@thana_small2 == getarg(2)) && (@thana_big1 == getarg(2)) && (@thana_big2 == getarg(2)) && (@thana_big3 == getarg(2))) return 1;
			return 0;
							
		case 2:
			set getarg(1),getarg(3);
			if((@thana_small1 == getarg(3)) && (@thana_small2 == getarg(3)) && (@thana_big1 == getarg(3)) && (@thana_big2 == getarg(3)) && (@thana_big3 == getarg(3))) return 1;
			return 0;
							
		case 3:
			set getarg(1),getarg(4);
			if((@thana_small1 == getarg(4)) && (@thana_small2 == getarg(4)) && (@thana_big1 == getarg(4)) && (@thana_big2 == getarg(4)) && (@thana_big3 == getarg(4))) return 1;
			return 0;
	}
}

tha_t09,19,158,0	script	Machine#thana0	111,{

	if((countitem(7425)) || (countitem(7430)))
	{
		mes "^3355FFVous trouvez une machine étrange qui semble hors d'usage.^000000";
		close;
	}
	mes "^3355FFVous trouvez une machine qui émet une faible lumière et un léger bourdonnement.";
	mes "Il y a un écran ainsi que plusieurs serrures de couleur sur l'avant de la machine.^000000";
	if(!((countitem(7421)) || (countitem(7426))) && ((countitem(7422)) || (countitem(7427))) && ((countitem(7423)) || (countitem(7428))) && ((countitem(7424)) || (countitem(7429)))) close;
	next;
	mes "^3355FFVous remarquez aussi certains emplacements qui semblent parfaits pour vos clés et vos pierres enchantées.";
	next;
	input @input$;
	if (@input$ == "Clés" || @input$ == "Pierres Enchantées" || @input$ == "Pierre Enchantée" || @input$ == "Clé")
	{
		mes "^3355FFVous insérez les clés dans la serrure en fonction de leur couleur, et placez les Pierres Enchantées dans leurs emplacements sur la machine.";
		mes "Les pierres commencent à briller et un texte s'affiche à l'écran tandis que le compartiment sous le moniteur s'ouvre.^000000";
		next;
		switch( select( "Lire le texte à l'écran.","Examiner le compartiment.","Annuler." ) )
		{
			case 1:
				mes "[Sauvegarde]";
				mes "^426F42Tandis que je suivais une piste vers le nord, je franchissais de nombreux endroits déserts.";
				mes "J'ai fini par tomber sur un petit village où j'ai appris l'existence d'une tour où les humains ne pouvaient entrer.^000000";
				next;
				mes "[Sauvegarde]";
				mes "^426F42J'ai immédiatement compris qu'elle devait s'être rendue à la tour.";
				mes "Je me suis donc dirigé vers celle-ci. Mais lorsque je fus enfin arrivé, ce fût un choc. Le bâtiment était si grotesque qu'il ne ressemblait à aucune construction humaine.^000000";
				next;
				mes "^426F42Mais j'étais aussi émerveillé~";
				mes "Une technologie très avancée avait dû être employée afin de bâtir la structure complexe de la tour.";
				mes "J'appris alors un fait intéressant tandis que j'explorais celle-ci...^000000";
				next;
				mes "^3355FFVous avez terminé de lire le texte affiché à l'écran.^000000";
				close;
				
			case 2:
				mes "^3355FFVous examinez le compartiment sous le moniteur et trouvez une clé étrange.";
				mes "La machine s'arrête sitôt que vous la prenez.";
				mes "Vous récupérez alors les Pierres Enchantées ainsi que les autres clés.^000000";
				getitem 7425,1;
				close;
			
			case 3:
				mes "^3355FFVous récupérez les Pierres Enchantées ainsi que les clés que vous aviez insérées dans la machine.^000000";
				close;
		}
	}
	mes "Vous tentez d'insérer un "+@input$+", mais rien ne se passe.";
	close;
}

tha_t04,150,44,0	script	Sceau#thana1	111,{

	if(!countitem(7423))
	{
		mes "^3355FFCette zone est protégée par un pouvoir étrange.";
		mes "Vous essayez de toucher le sceau mais il se met alors à bourdonner bruyamment et repousse votre main.^000000";
		percentheal -10,0;
		close;
	}
	mes "^3355FFCette zone est protégée par un pouvoir étrange.";
	mes "Vous essayez de toucher le sceau mais il se met alors à bourdonner bruyamment et repousse votre main créant une sorte de lumière bleue.^000000";
	next;
	switch( select( "L'examiner.","Je n'arriverai jamais à briser ce sceau!" ) )
	{
		case 1:
			input @input$;
			if (@input$ == "Clé Bleue")
			{
				mes "^3355FFVous approchez précautionneusement la clé bleue du sceau.";
				mes "Étrangement, votre main n'est cette fois pas repoussée, et le sceau commence à émettre une lumière mystérieuse.^000000";
				next;
				mes "^3355FFVous trouvez une petite serrure sur le sceau. Vous y insérez la clé bleue et la tournez doucement.";
				mes "La lumière émanant du sceau s'estompe, révélant une Pierre Enchantée.";
				mes "Lorsque vous vous en emparez, les souvenirs d'une autre personne se présentent à votre esprit.^000000";
				next;
				mes "^333333Thanatos! Nous venons de recevoir un message de la guilde.";
				mes "Ils veulent que nous arrêtions ce que nous sommes en train de faire et que nous partions maintenant!^000000";
				mes " ";
				mes "^333333Nous... Nous devons nous hâter...^000000";
				next;
				mes "......";
				mes ".........";
				mes "............";
				next;
				mes "^3355FFLes visions s'estompent aussi soudainement qu'elles étaient venues à votre esprit.";
				mes "Qu'a-t-il bien pu se passer autrefois?^000000";
				delitem 7423,1;
				getitem 7428,1;
				close;
			}
			mes "^3355FFIl vous faudra tenter autre chose afin de briser ce sceau.";
			mes "De quoi pourriez-vous donc avoir besoin?^000000";
			close;
		
		case 2:
			mes "^3355FFVous vous écartez du sceau, réticent à l'idée d'avoir à utiliser un pouvoir qui vous repousse d'avance.^000000";
			close;
	}
}

tha_t05,218,116,0	script	Sceau#thana2	111,{

	if(!countitem(7421))
	{
		mes "^3355FFCette zone est protégée par un pouvoir étrange.";
		mes "Vous essayez de toucher le sceau mais il se met alors à bourdonner bruyamment et repousse votre main.^000000";
		percentheal -10,0;
		close;
	}
	mes "^3355FFCette zone est protégée par un pouvoir étrange.";
	mes "Vous essayez de toucher le sceau mais il se met alors à bourdonner bruyamment et repousse votre main créant une sorte de lumière rouge.^000000";
	next;
	switch( select( "L'examiner.","Je n'arriverai jamais à briser ce sceau!" ) )
	{
		case 1:
			input @input$;
			if (@input$ == "Clé Rouge")
			{
				mes "^3355FFVous approchez précautionneusement la clé rouge du sceau.";
				mes "Étrangement, votre main n'est cette fois pas repoussée, et le sceau commence à émettre une lumière mystérieuse.^000000";
				next;
				mes "^3355FFVous trouvez une petite serrure sur le sceau. Vous y insérez la clé rouge et la tournez doucement.";
				mes "La lumière émanant du sceau s'estompe, révélant une Pierre Enchantée.";
				mes "Lorsque vous vous en emparez les souvenirs d'une autre personne se présentent à votre esprit.^000000";
				next;
				mes "...Il fut alors décidé d'envoyer plusieurs Assassins Cross pour vaincre Satan Morroc.";
				mes "Mais à dire vrai, les chances de succès ne dépassent pas 1%.";
				mes "C'est mieux que rien mais... Mince, on parle de Satan Morroc là!^000000";
				next;
				mes "......";
				mes ".........";
				mes "............";
				next;
				mes "^3355FFLes visions s'estompent aussi soudainement qu'elles étaient venues à votre esprit.";
				mes "Qu'a-t-il bien pu se passer autrefois?^000000";
				delitem 7421,1;
				getitem 7426,1;
				close;
			}
			mes "^3355FFIl vous faudra tenter autre chose afin de briser ce sceau.";
			mes "De quoi pourriez-vous donc avoir besoin?^000000";
			close;
		
		case 2:
			mes "^3355FFVous vous écartez du sceau, réticent à l'idée d'avoir à utiliser un pouvoir qui vous repousse d'avance.^000000";
			close;
	}
}

tha_t06,226,230,0	script	Sceau#thana3	111,{

	if(!countitem(7425))
	{
		mes "^3355FFCette zone est protégée par un pouvoir étrange.";
		mes "Vous essayez de toucher le sceau mais il se met alors à bourdonner bruyamment et repousse votre main.^000000";
		percentheal -10,0;
		close;
	}
	mes "^3355FFCette zone est protégée par un pouvoir étrange.";
	mes "Vous essayez de toucher le sceau mais il se met alors à bourdonner bruyamment et repousse votre main créant une sorte de lumière noire.^000000";
	next;
	switch( select( "L'examiner.","Je n'arriverai jamais à briser ce sceau!" ) )
	{
		case 1:
			input @input$;
			if (@input$ == "Clé Noire")
			{
				mes "^3355FFVous approchez précautionneusement la clé noire du sceau.";
				mes "Étrangement, votre main n'est cette fois pas repoussée, et le sceau commence à émettre une lumière mystérieuse.^000000";
				next;
				mes "^3355FFVous trouvez une petite serrure sur le sceau. Vous y insérez la clé noire et la tournez doucement.";
				mes "La lumière émanant du sceau s'estompe, révélant une Pierre Enchantée.";
				mes "Lorsque vous vous en emparez les souvenirs d'une autre personne se présentent à votre esprit.^000000";
				next;
				mes "^333333Nous l'avons trouvée!";
				mes "Il doit s'agir de la tour où Satan Morroc rassemble ses minions...";
				mes "Dieu tout puissant... Il y en a des milliers... Nous reste-t-il le moindre espoir? Reste-t-il le moindre espoir à l'humanité toute entière?^000000";
				next;
				mes "......";
				mes ".........";
				mes "............";
				next;
				mes "^3355FFLes visions s'estompent aussi soudainement qu'elles étaient venues à votre esprit.";
				mes "Qu'a-t-il bien pu se passer autrefois?^000000";
				delitem 7425,1;
				getitem 7430,1;
				close;
			}
			mes "^3355FFIl vous faudra tenter autre chose afin de briser ce sceau.";
			mes "De quoi pourriez-vous donc avoir besoin?^000000";
			close;
		
		case 2:
			mes "^3355FFVous vous écartez du sceau, réticent à l'idée d'avoir à utiliser un pouvoir qui vous repousse d'avance.^000000";
			close;
	}
}

tha_t07,113,129,0	script	Sceau#thana4	111,{

	if(!countitem(7422))
	{
		mes "^3355FFCette zone est protégée par un pouvoir étrange.";
		mes "Vous essayez de toucher le sceau mais il se met alors à bourdonner bruyamment et repousse votre main.^000000";
		percentheal -10,0;
		close;
	}
	mes "^3355FFCette zone est protégée par un pouvoir étrange.";
	mes "Vous essayez de toucher le sceau mais il se met alors à bourdonner bruyamment et repousse votre main créant une sorte de lumière jaune.^000000";
	next;
	switch( select( "L'examiner.","Je n'arriverai jamais à briser ce sceau!" ) )
	{
		case 1:
			input @input$;
			if (@input$ == "Clé Jaune")
			{
				mes "^3355FFVous approchez précautionneusement la clé jaune du sceau.";
				mes "Étrangement, votre main n'est cette fois pas repoussée, et le sceau commence à émettre une lumière mystérieuse.^000000";
				next;
				mes "^3355FFVous trouvez une petite serrure sur le sceau. Vous y insérez la clé jaune et la tournez doucement.";
				mes "La lumière émanant du sceau s'estompe, révélant une Pierre Enchantée.";
				mes "Lorsque vous vous en emparez les souvenirs d'une autre personne se présentent à votre esprit.^000000";

				next;
				mes "^333333" + ( isday() ? "Bonjour" : "Bonsoir" ) + ", je suis Lucil. Je suis en retard, désolé, mais j'avais un long chemin à parcourir depuis le lieu de ma dernière mission...^000000";
				mes " ";
				mes "^333333Je suis Thanatos...^000000";
				next;
				mes "^333333Pourquoi sa présence me trouble-t-elle?";
				mes "Je vois tout ce qui m'échappait auparavant, toutes les choses que je veux, et tout ce que je voudrais être. Et elle les apporte, elle me complète. Comme c'est... étrange...^000000";
				mes "'Elle me trouble vraiment... comme si je venais de trouver ma moitié perdue...'";
				next;
				mes "......";
				mes ".........";
				mes "............";
				next;
				mes "^3355FFLes visions s'estompent aussi soudainement qu'elles étaient venues à votre esprit.";
				mes "Qu'a-t-il bien pu se passer autrefois?^000000";
				delitem 7422,1;
				getitem 7427,1;
				close;
			}
			mes "^3355FFIl vous faudra tenter autre chose afin de briser ce sceau.";
			mes "De quoi pourriez-vous donc avoir besoin?^000000";
			close;
		
		case 2:
			mes "^3355FFVous vous écartez du sceau, réticent à l'idée d'avoir à utiliser un pouvoir qui vous repousse d'avance.^000000";
			close;
	}
}

tha_t10,129,159,0	script	Sceau	111,{

	if(!countitem(7424))
	{
		mes "^3355FFCette zone est protégée par un pouvoir étrange.";
		mes "Vous essayez de toucher le sceau mais il se met alors à bourdonner bruyamment et repousse votre main.^000000";
		percentheal -10,0;
		close;
	}
	mes "^3355FFCette zone est protégée par un pouvoir étrange.";
	mes "Vous essayez de toucher le sceau mais il se met alors à bourdonner bruyamment et repousse votre main créant une sorte de lumière verte.^000000";
	next;
	switch( select( "L'examiner.","Je n'arriverai jamais à briser ce sceau!" ) )
	{
		case 1:
			input @input$;
			if (@input$ == "Clé Verte")
			{
				mes "^3355FFVous approchez précautionneusement la clé verte du sceau.";
				mes "Étrangement, votre main n'est cette fois pas repoussée, et le sceau commence à émettre une lumière mystérieuse.^000000";
				next;
				mes "^3355FFVous trouvez une petite serrure sur le sceau. Vous y insérez la clé verte et la tournez doucement.";
				mes "La lumière émanant du sceau s'estompe, révélant une Pierre Enchantée.";
				mes "Lorsque vous vous en emparez les souvenirs d'une autre personne se présentent à votre esprit.^000000";

				next;
				mes "^333333Cette bataille scellera le destin de l'humanité toute entière.";
				mes "Nous devons vaincre Satan Morroc. Il n'y a aucune alternative. Qui est avec moi?";
				mes "^333333*Tousse* Le démon est trop puissant! N... nous ne pouvons pas...^000000";
				next;
				mes "^333333Misérables humains.";
				mes "Vous auriez dû vous y attendre.";
				mes "...Cela ne se peut! Est-ce~? ";
				mes "^333333GGGRRRRAH! C-COMMENT OSEZ-VOUS HUMAINS! COMMENT OSEZ VOOOOOOOUS....! ";
				next;
				mes "......";
				mes ".........";
				mes "............";
				next;
				mes "^3355FFLes visions s'estompent aussi soudainement qu'elles étaient venues à votre esprit.";
				mes "Qu'a-t-il bien pu se passer autrefois?^000000";
				delitem 7424,1;
				getitem 7429,1;
				close;
			}
			mes "^3355FFIl vous faudra tenter autre chose afin de briser ce sceau.";
			mes "De quoi pourriez-vous donc avoir besoin?^000000";
			close;
		
		case 2:
			mes "^3355FFVous vous écartez du sceau, réticent à l'idée d'avoir à utiliser un pouvoir qui vous repousse d'avance.^000000";
			close;
	}
}

tha_t12,96,58,0	script	Statue de Pierre#thana1	111,{

	if(!$@thana_summon)
	{
		mes "^3355FFVous trouvez une statue de pierre avec un trou visible au niveau de la poitrine.^000000";
		if((countitem(7426)) && (countitem(7427)) && (countitem(7428)) && (countitem(7429)) && (countitem(7430)))
		{
			next;
			mes "^3355FFTandis que vous approchez de la statue, celle-ci commence à briller d'une lumière rouge scintillante, tout comme votre Pierre Enchantée.^000000";
			next;
			switch( select( "Insérer la Pierre Enchantée dans la statue.","Annuler." ) )
			{
				case 1:
					mes "^3355FFLa statue se met à briller encore plus intensément d'une lumière mystérieuse après que vous ayez inséré la Pierre Enchantée Rouge.^000000";
					delitem 7426,1;
					specialeffect EF_BEGINSPELL3;
					enablenpc "tteffect2";
					donpcevent "tteffect2::OnGlow";
					set $@thana_summon,1;
					close;
				
				case 2:
					mes "^3355FFVous décidez de ne pas insérer la Pierre Enchantée et d'examiner la zone plus en détail.^000000";
					close;
			}
		}
		else if((countitem(7426)) || (countitem(7427)) || (countitem(7428)) || (countitem(7429)) || (countitem(7430)))
		{
			next;
			mes "^3355FFTandis que vous approchez de la statue, l'une de votre Pierres Enchantées se met à briller.";
			mes "Cependant, la statue elle-même ne réagit pas.";
			mes "Vous avez sans doute besoin de toutes les pierres pour l'activer complètement.^000000";
			close;
		}
		else close;
	}
	else if($@thana_summon == 6)
	{
		mes "^3355FFUne lumière intense émane de la statue, rendant les alentours si chauds que vous ne pouvez approcher.^000000";
		close;
	}
	else
	{
		mes "^3355FFCette statue est entourée d'une étrange lumière.";
		mes "Des forces mystérieuses vous empêchent de l'approcher.^000000";
		close;
	}
}

tha_t12,104,18,0	script	Statue de Pierre#thana2	111,{

	if($@thana_summon == 2)
	{
		mes "^3355FFVous trouvez une statue de pierre avec un trou visible au niveau de la poitrine.^000000";
		if(countitem(7428))
		{
			next;
			mes "^3355FFTandis que vous approchez de la statue, votre Pierre Enchantée Bleue commence à briller d'une lumière scintillante, à laquelle la statue fait écho en s'entourant d'une lueur rougeâtre.^000000";
			next;
			switch( select( "Insérer la Pierre Enchantée dans la statue.","Annuler." ) )
			{
				case 1:
					mes "^3355FFLa statue se met à briller encore plus intensément d'une lumière mystérieuse après que vous ayez inséré la Pierre Enchantée.^000000";
					delitem 7428,1;
					specialeffect EF_BEGINSPELL3;
					enablenpc "tteffect5";
					donpcevent "tteffect5::OnGlow";
					set $@thana_summon,3;
					close;
				
				case 2:
					mes "^3355FFVous décidez de ne pas insérer la Pierre Enchantée et d'examiner la zone plus en détail.^000000";
					close;
			}
		}
		close;
	}
	else if($@thana_summon == 6)
	{
		mes "^3355FFUne lumière intense émane de la statue, rendant les alentours si chauds que vous ne pouvez approcher.^000000";
		close;
	}
	else
	{
		mes "^3355FFCette statue est entourée d'une étrange lumière.";
		mes "Des forces mystérieuses vous empêchent de l'approcher.^000000";
		close;
	}
}

tha_t12,128,86,0	script	Statue de Pierre#thana3	111,{

	if($@thana_summon == 3)
	{
		mes "^3355FFVous trouvez une statue de pierre avec un trou visible au niveau de la poitrine.^000000";
		if(countitem(7430))
		{
			next;
			mes "^3355FFTandis que vous approchez de la statue, une obscurité inquiétante émane de votre Pierre Enchantée Noire.";
			mes "En réponse, la statue commence à briller d'une sinistre lumière rouge.^000000";
			next;
			switch( select( "Insérer la Pierre Enchantée dans la statue.","Annuler." ) )
			{
				case 1:
					mes "^3355FFLa statue se met à briller encore plus intensément d'une lumière mystérieuse après que vous ayez inséré la Pierre Enchantée Noire.^000000";
					delitem 7430,1;
					specialeffect EF_BEGINSPELL7;
					enablenpc "tteffect1";
					donpcevent "tteffect1::OnGlow";
					set $@thana_summon,4;
					close;
				
				case 2:
					mes "^3355FFVous décidez de ne pas insérer la Pierre Enchantée et d'examiner la zone plus en détail.^000000";
					close;
			}
		}
		close;
	}
	else if($@thana_summon == 6)
	{
		mes "^3355FFUne lumière intense émane de la statue, rendant les alentours si chauds que vous ne pouvez approcher.^000000";
		close;
	}
	else
	{
		mes "^3355FFCette statue est entourée d'une étrange lumière.";
		mes "Des forces mystérieuses vous empêchent de l'approcher.^000000";
		close;
	}
}

tha_t12,161,58,0	script	Statue de Pierre#thana4	111,{

	if($@thana_summon == 1)
	{
		mes "^3355FFVous trouvez une statue de pierre avec un trou visible au niveau de la poitrine.^000000";
		if(countitem(7427))
		{
			next;
			mes "^3355FFTandis que vous approchez de la statue, votre Pierre Enchantée Jaune commence à briller d'un jaune étincelant, et la statue s'entoure d'une aura rougeâtre.^000000";
			next;
			switch( select( "Insérer la Pierre Enchantée dans la statue.","Annuler." ) )
			{
				case 1:
					mes "^3355FFLa statue se met à briller encore plus intensément d'une lumière mystérieuse après que vous ayez inséré la Pierre Enchantée Jaune.^000000";
					delitem 7427,1;
					specialeffect EF_BEGINSPELL5;
					enablenpc "tteffect3";
					donpcevent "tteffect3::OnGlow";
					set $@thana_summon,2;
					close;
				
				case 2:
					mes "^3355FFVous décidez de ne pas insérer la Pierre Enchantée et d'examiner la zone plus en détail.^000000";
					close;
			}
		}
		close;
	}
	else if($@thana_summon == 6)
	{
		mes "^3355FFUne lumière intense émane de la statue, rendant les alentours si chauds que vous ne pouvez approcher.^000000";
		close;
	}
	else
	{
		mes "^3355FFCette statue est entourée d'une étrange lumière.";
		mes "Des forces mystérieuses vous empêchent de l'approcher.^000000";
		close;
	}
}

tha_t12,154,18,0	script	Statue de Pierre#thana5	111,{

	if($@thana_summon == 4)
	{
		mes "^3355FFVous trouvez une statue de pierre avec un trou visible au niveau de la poitrine.^000000";
		if(countitem(7429))
		{
			next;
			mes "^3355FFTandis que vous approchez de la statue, une faible lumière verdâtre commence à irradier de votre Pierre Enchantée Verte, tandis que la statue commence à briller d'un rouge intense.^000000";
			next;
			switch( select( "Insérer la Pierre Enchantée dans la statue.","Annuler." ) )
			{
				case 1:
					mes "^3355FFLa statue se met à briller encore plus intensément d'une lumière mystérieuse après que vous ayez inséré la Pierre Enchantée Verte.^000000";
					specialeffect EF_BEGINSPELL4;
					enablenpc "tteffect4";
					donpcevent "tteffect4::OnGlow";
					delitem 7429,1;
					next;
					mes "^3355FFLes symboles magiques tracés sur le sol au centre des cinq statues ont été activés et émettent une énergie puissante et terrifiante.^000000";
					set $@thana_summon,5;
					set $@thana_summon2,0;
					enablenpc "WarpThana";
					close;
				
				case 2:
					mes "^3355FFVous décidez de ne pas insérer la Pierre Enchantée et d'examiner la zone plus en détail.^000000";
					close;
			}
		}
		close;
	}
	else if($@thana_summon == 6)
	{
		mes "^3355FFUne lumière intense émane de la statue, rendant les alentours si chauds que vous ne pouvez approcher.^000000";
		close;
	}
	else
	{
		mes "^3355FFCette statue est entourée d'une étrange lumière.";
		mes "Des forces mystérieuses vous empêchent de l'approcher.^000000";
		close;
	}
}

tha_t12,129,56,0	script	tteffect1	139,{

OnInit:
	disablenpc "tteffect1";
	end;
	
OnGlow:
	initnpctimer;
	end;
	
OnTimer500:
OnTimer1000:
OnTimer1500:
OnTimer2000:
OnTimer2500:
	specialeffect EF_BEGINSPELL7;
	end;
	
OnTimer3000:
	specialeffect EF_BEGINSPELL7;
	stopnpctimer;
	if($@thana_summon == 6)	end;
	initnpctimer;
	end;

OnStop:
	stopnpctimer;
	end;
}

tha_t12,125,52,0	script	tteffect2	139,{

OnInit:
	disablenpc "tteffect2";
	end;
	
OnGlow:
	initnpctimer;
	end;
	
OnTimer500:
OnTimer1000:
OnTimer1500:
OnTimer2000:
OnTimer2500:
	specialeffect EF_BEGINSPELL3;
	end;
	
OnTimer3000:
	specialeffect EF_BEGINSPELL3;
	stopnpctimer;
	if($@thana_summon == 6)	end;
	initnpctimer;
	end;

OnStop:
	stopnpctimer;
	end;
}

tha_t12,134,52,0	script	tteffect3	139,{

OnInit:
	disablenpc "tteffect3";
	end;
	
OnGlow:
	initnpctimer;
	end;
	
OnTimer500:
OnTimer1000:
OnTimer1500:
OnTimer2000:
OnTimer2500:
	specialeffect EF_BEGINSPELL5;
	end;
	
OnTimer3000:
	specialeffect EF_BEGINSPELL5;
	stopnpctimer;
	if($@thana_summon == 6)	end;
	initnpctimer;
	end;
	
OnStop:
	stopnpctimer;
	end;
}

tha_t12,132,47,0	script	tteffect4	139,{

OnInit:
	disablenpc "tteffect4";
	end;
	
OnGlow:
	initnpctimer;
	end;
	
OnTimer500:
OnTimer1000:
OnTimer1500:
OnTimer2000:
OnTimer2500:
	specialeffect EF_BEGINSPELL4;
	end;
	
OnTimer3000:
	specialeffect EF_BEGINSPELL4;
	stopnpctimer;
	if($@thana_summon == 6)	end;
	initnpctimer;
	end;
	
OnStop:
	stopnpctimer;
	end;
}

tha_t12,127,47,0	script	tteffect5	139,{

OnInit:
	disablenpc "tteffect5";
	end;
	
OnGlow:
	initnpctimer;
	end;
	
OnTimer500:
OnTimer1000:
OnTimer1500:
OnTimer2000:
OnTimer2500:
	specialeffect EF_BEGINSPELL2;
	end;
	
OnTimer3000:
	specialeffect EF_BEGINSPELL2;
	stopnpctimer;
	if($@thana_summon == 6)	end;
	initnpctimer;
	end;
	
OnStop:
	stopnpctimer;
	end;
}

tha_t12,130,52,0	script	WarpThana	45,1,1,{

OnInit:
	disablenpc "WarpThana";
	end;
	
OnTouch:
	if($@thana_summon == 5) warp "thana_boss",136,116;
	else
	{
		donpcevent "tteffect1::OnStop";
		donpcevent "tteffect2::OnStop";
		donpcevent "tteffect3::OnStop";
		donpcevent "tteffect4::OnStop";
		donpcevent "tteffect5::OnStop";
		disablenpc "WarpThana";
		end;
	}
}

thana_boss,217,167,0	script	Promontoire#1	111,3,3,{

	end;
	
OnTouch:
	if($@thana_summon == 6)
	{
		mes "^3355FFVous ne pouvez approcher le promontoire à cause de la chaleur intense qu'il dégage.^000000";
		close;
	}
	mes "^3355FFIl y a un trou de forme étrange au centre du promontoire.^000000";
	if (countitem(7437))
	{
		mes "^3355FFOn dirait qu'un Fragment de Tristesse s'y emboiterait parfaitement.^000000";
	}
	next;
	input @input$;
	if(countitem(7437))
	{
		if(@input$ == "Fragment de Tristesse")
		{
			mes "^3355FFVous y insérez le Fragment de Tristesse et le promontoire se met à briller plus intensément encore.^000000";
			delitem 7437,1;
			monster "thana_boss",217,167,"Tristesse",1711,1,"#Death::OnDead";
			disablenpc "Promontoire#1";
			close;
		}
	}
	mes "^3355FFRien ne se passe. Vous devrez tenter autre chose.^000000";
	close;	
}

thana_boss,202,75,0	script	Promontoire#2	111,3,3,{

	end;
	
OnTouch:
	if($@thana_summon == 6)
	{
		mes "^3355FFVous ne pouvez approcher le promontoire à cause de la chaleur intense qu'il dégage.^000000";
		close;
	}
	mes "^3355FFIl y a un trou de forme étrange au centre du promontoire.^000000";
	if (countitem(7436))
	{
		mes "^3355FFOn dirait qu'un Fragment d'Agonie s'y emboiterait parfaitement.^000000";
	}
	next;
	input @input$;
	if(countitem(7436))
	{
		if(@input$ == "Fragment d'Agonie")
		{
			mes "^3355FFVous y insérez le Fragment d'Agonie et le promontoire se met à briller plus intensément encore.^000000";
			delitem 7436,1;
			monster "thana_boss",202,75,"Agonie",1712,1,"#Death::OnDead";
			disablenpc "Promontoire#2";
			close;
		}
	}
	mes "^3355FFRien ne se passe. Vous devrez tenter autre chose.^000000";
	close;
}

thana_boss,80,76,0	script	Promontoire#3	111,3,3,{

	end;
	
OnTouch:
	if($@thana_summon == 6)
	{
		mes "^3355FFVous ne pouvez approcher le promontoire à cause de la chaleur intense qu'il dégage.^000000";
		close;
	}
	mes "^3355FFIl y a un trou de forme étrange au centre du promontoire.^000000";
	if (countitem(7438))
	{
		mes "^3355FFOn dirait qu'un Fragment de Haine s'y emboiterait parfaitement.^000000";
	}
	next;
	input @input$;
	if(countitem(7438))
	{
		if(@input$ == "Fragment de Haine")
		{
			mes "^3355FFVous y insérez le Fragment de Haine et le promontoire se met à briller plus intensément encore.^000000";
			delitem 7438,1;
			monster "thana_boss",80,76,"Haine",1709,1,"#Death::OnDead";
			disablenpc "Promontoire#3";
			close;
		}
	}
	mes "^3355FFRien ne se passe. Vous devrez tenter autre chose.^000000";
	close;
}

thana_boss,62,171,0	script	Promontoire#4	111,3,3,{

	end;
	
OnTouch:
	if($@thana_summon == 6)
	{
		mes "^3355FFVous ne pouvez approcher le promontoire à cause de la chaleur intense qu'il dégage.^000000";
		close;
	}
	mes "^3355FFIl y a un trou de forme étrange au centre du promontoire.^000000";
	if (countitem(7439))
	{
		mes "^3355FFOn dirait qu'un Fragment de Désespoir s'y emboiterait parfaitement.^000000";
	}
	next;
	input @input$;
	if(countitem(7439))
	{
		if(@input$ == "Fragment de Désespoir")
		{
			mes "^3355FFVous y insérez le Fragment de Désespoir et le promontoire se met à briller plus intensément encore.^000000";
			delitem 7439,1;
			monster "thana_boss",62,171,"Désespoir",1710,1,"#Death::OnDead";
			disablenpc "Promontoire#4";
			close;
		}
	}
	mes "^3355FFRien ne se passe. Vous devrez tenter autre chose.^000000";
	close;	
}

thana_boss,141,218,0	script	Promontoire#5	111,3,3,{

	end;
	
OnTouch:
	if($@thana_summon2 > 3)
	{
		mes "^3355FFAlors que vous approchez du promontoire, il devient de plus en plus brillant, jusqu'à devenir aveuglant.^000000";
		set $@thana_wave,4;
		monster "thana_boss",140,217,"Désespoir",1710,1,"#Death::OnWave";
		monster "thana_boss",140,216,"Haine",1709,1,"#Death::OnWave";
		monster "thana_boss",141,217,"Tristesse",1711,1,"#Death::OnWave";
		monster "thana_boss",141,216,"Agonie",1712,1,"#Death::OnWave";
		disablenpc "Promontoire#5";
		close;
	}
	input @input$;
	mes "^3355FFRien ne se passe.^000000";
	close;
}

thana_boss,5,5,0	script	#thanasummon	-1,{

	end;

OnSummon:
	monster "thana_boss",139,129,"Fantôme de Thanatos",1708,1,"#Death::OnThanaDead";
	end;

}

thana_boss,3,3,0	script	#thanatimer	-1,{

OnInit:
	set $@thana_summon,0;
	set $@thana_summon2,0;
	end;

OnActive:
	initnpctimer;
	end;
	
OnTimer1000:
	mapannounce "thana_boss","GGGGRRRRRRR!",1;
	end;

OnTimer2000:
	mapannounce "thana_boss","*Bzzzz Bzzzz",1;
	end;

OnTimer3000:
	mapannounce "thana_boss","*Crik Crik*",1;
	end;

OnTimer4000:
	mapannounce "thana_boss","*Zzzzrt Zzzzrt*",1;
	end;

OnTimer5000:
	mapannounce "thana_boss","*Crik Crik*",1;
	end;

OnTimer60000:
	mapwarp "thana_boss","tha_t12",130,47;
	set $@thana_summon2,0;
	enablenpc "Promontoire#1";
	enablenpc "Promontoire#2";
	enablenpc "Promontoire#3";
	enablenpc "Promontoire#4";
	enablenpc "Promontoire#5";
	end;
	
OnTimer7200000:
	killmonsterall "thana_boss";
	set $@thana_summon,0;
	stopnpctimer;
	end;
}

thana_boss,1,1,0	script	#Death	-1,{

OnDead:
	set $@thana_summon2,$@thana_summon2 +1;
	end;

OnWave:
	set $@thana_wave,$@thana_wave -1;
	if($@thana_wave < 1)
	{
		donpcevent "#thanasummon::OnSummon";
	}
	end;
	
OnThanaDead:
	donpcevent "#thanatimer::OnActive";
	set $@thana_summon,6;
	end;
}

tha_t06,119,120,0	script	thana6-7	45,1,1,{
	if (((Upper == 1) && ((Class > Job_Thief_High) && (Class < Job_Baby))) || (((Class == Job_Gunslinger) || (Class == Job_Ninja) || (BaseClass == Job_Taekwon)) && (BaseLevel >= 95))) {
		warp "thana_step",69,369;
		end;
	}
	else {
		mes "^3355FFUne force écrasante s'oppose à vous, vous empêchant de continuer dans cette direction...^000000";
		close;
	}
}